マクロ作成関連

1.1 複数のDLLを使う方法

作成：2009/08/30　更新：2011/12/17

秀丸エディタVer.8β8より、loaddll関数により、複数DLLのロードが可能になりました。詳細はマクロヘルプ-DLL呼び出し機能にある、「複数のDLLを扱う場合（V8.00以降）」を参照して下さい。

秀丸エディタではVer.3.02以降、外部DLLを使用できるようになりました。一度に使用できるDLLは一つだけなので、複数のDLLを使用する場合、使用するDLLが変わるたびにDLLの解放・DLLのロードを繰り返す必要があります。複数DLLの処理が完全に別々になる（DLL1を使った処理が全て終了後、DLL2を使う処理を行う）なら順番にロードすれば特に問題はありませんが、別DLLの関数を交互に使いたい場合は、DLLのロードと解放を頻繁に行わなくてはいけません。

• 複数DLLを使う方法１

  以下のDLLを使う方法があります。

  • 杉浦まさきさんのDLL Wrapper
  • 手風琴さんのDLLProxy 2011/12/17現在、アクセス不可

  これらのDLLを使えば一度に複数のDLLをロードすることが出来ます。 DLL経由で他のDLLをロードするため、秀丸エディタからは一つのDLLをロードすればOKです。

• 複数DLLを使う方法２

  外部のDLLを使わない方法です。秀丸エディタの制限を逆手に取った方法なので、将来的には使えなくなるかもしれません。

  マクロ自体は秀丸エディタが切り替わっても問題はありませんが、loaddllで読み込んだDLLは、読み込んだ秀丸エディタでしか有効になりません。そこで、使用したいDLLの数だけ秀丸エディタ（ステルスで）を開き、個々にDLLをロードします。 DLL関数を使う場合は、setactivehidemaru文を使い、使用したいdllをロードした秀丸エディタに切り換えて、DLL関数を使用します。

                      DLL1をロードした秀丸エディタ
                        ↑
  メインの秀丸エディタ──┤　使用するDLLごとに秀丸エディタを切り換える
                        ↓
                      DLL2をロードした秀丸エディタ

  欠点としては、秀丸エディタの管理が面倒なことと、ウィンドウの切り替えを行うために、ちらつく場合があることです。

目次へ

1.2 DLLの有効範囲

作成：2009/09/06　更新：2011/12/17

複数のDLLを使う方法でも書きましたが、loaddll文/関数の有効範囲はコマンドを実行した秀丸エディタだけです。秀丸エディタを切り換えた場合は新たにロードし直す必要があります。

loaddll "test.dll";
#n = dllfunc("function1"); ←　OK
　　　・
openfile "hogehoge.txt";　　←　新しい秀丸エディタを開いたので、test.dllはロードされていない。
#n = dllfunc("function1"); ←　NG　test.dllがロードされていないので、エラーになる。
　　　・
　　　・

マクロヘルプ-DLL呼び出し機能にある、「loaddll（文）」の項目を、参照して下さい。

秀丸担当さんによると、

別の秀丸エディタではプロセスが別になっているので、
原理的にDLLを共通にすることはできないです。

(turukame.3:03567より抜粋) とのことです。

1.3 ２バイト文字の判定

作成：2009/08/23　更新：2009/08/31

マクロでmidstrを使って文字を切り出しascii関数に入れると、２バイト文字の先頭バイトの場合は0x8100以上をかえします。(下位バイトは常に00になる) これを利用すれば２バイト文字の判定は可能です。

秀丸エディタ Ver.8β6 より、ascii関数の仕様が変更され、１バイトだけの場合は、マルチバイト文字の上位バイト範囲内でも、そのまま文字コードを返します。２バイト以上で、Shift_JIS範囲内の場合は、Shift_JISコードを返します。

ちなみに、２バイト文字の下位バイトは0x40～0x7E、0x80～0xFCであるため、 ASCIIコードの範囲と重なっています。そのため、0xXX00 か 0xXX の値がかえってくるので、下位バイトのみで判定することは出来ません。必ず上位バイト側からチェックする必要があります。

マクロのascii関数は、0x81～0x9F、0xE0～0xEFの範囲（２バイト文字の先頭バイト割り付け範囲）を引数に与えられると8ビットシフトし0xXX00で返しているだけです。

実験マクロ

debuginfo 1;
$test = "012３４５6７";
##len = strlen($test);
##cnt = 0;
while(##cnt < ##len){
   $$check = midstr($test, ##cnt, 1);
   debuginfo "check = " + $$check + " hex = " + hex(ascii($$check)) + "\n";
   ##cnt = ##cnt  + 1;
}
endmacro;

実行結果

check = 0 hex = 30
check = 1 hex = 31
check = 2 hex = 32
check = ・hex = 8200
check = R hex = 52
check = ・hex = 8200
check = S hex = 53
check = ・hex = 8200
check = T hex = 54
check = 6 hex = 36
check = ・hex = 8200
check = V hex = 56

実行結果(Ver.8β6以降)

check = 0 hex = 30
check = 1 hex = 31
check = 2 hex = 32
check = ・hex = 82
check = R hex = 52
check = ・hex = 82
check = S hex = 53
check = ・hex = 82
check = T hex = 54
check = 6 hex = 36
check = ・hex = 82
check = V hex = 56

実験マクロ　その２

debuginfo 1;
$test = "012３４５6７";
##len = strlen($test);
##cnt = 0;
while(##cnt < ##len){
   $$check = midstr($test, ##cnt, 2);
   debuginfo "check = " + $$check + " hex = " + hex(ascii($$check)) + "\n";
   ##cnt = ##cnt  + 1;
}
endmacro;

実行結果

check = 01 hex = 30
check = 12 hex = 31
check = 2・hex = 32
check = ３ hex = 8252
check = R・hex = 52
check = ４ hex = 8253
check = S・hex = 53
check = ５ hex = 8254
check = T6 hex = 54
check = 6・hex = 36
check = ７ hex = 8256
check = V  hex = 56

秀丸エディタ ver.8より、文字列を、文字単位で扱う関数が追加されています。文字単位で切り出し、コードを確認すれば、２バイト文字の判定は可能です。 (サロゲートペアとか、結合文字の場合の動作は、確認していません。)

実験マクロ　その３

debuginfo 1;
$test = "012３４５6７";
##cnt = 0;
##len = wcslen($test);
while(##cnt < ##len){
   $$check = wcsmidstr($test, ##cnt, 1);
   debuginfo "check = " + $$check + " hex = " + hex(ascii($$check)) + "\n";
   ##cnt = ##cnt  + 1;
}

実行結果(Ver.8β6以降)

check = 0  hex = 30
check = 1  hex = 31
check = 2  hex = 32
check = ３ hex = 8252
check = ４ hex = 8253
check = ５ hex = 8254
check = 6  hex = 36
check = ７ hex = 8256

秀丸エディタ上ではcodeキーワードを使えば判定できます。

目次へ

1.4 関連づけ起動

作成：2006/12/30

編集中のファイルを関連づけされたプログラムで開く方法です。

run "rundll32.exe url.dll,FileProtocolHandler " + filename;

起動するプログラムによっては、ファイル名を「"」囲ったり、filename3を使った方がいい場合もあります。

編集中のスクリプトの実行とか、編集中のhtmlファイルをブラウザで開くとかに使えます。

秀丸エディタVer.6.50β11より、openbyshell文に引数が指定できるようになり、上記方法を使用しなくても関連づけ起動が可能になりました。

目次へ

1.5 コンソールプログラムの実行

コンソールプログラムの中にはいまだに有用なプログラムが多数あります。

秀丸エディタからもコンソールプログラムが使えますが、実行中はコンソールが表示されてしまい見栄えが悪いです。（">con"の場合は大丈夫ですが。）コンソールを表示しないようにするには">nul"を指定すればいいのですが、リダイレクト出力を使用したい場合には使えない場合もあります。その場合はバッチファイルを経由して実行します。

バッチファイルの中身 test.bat

ruby -Ks test.rb %1 > %2

マクロの例

run "test.bat " + filename + " outfile > nul"

バッチファイルはマクロに添付するか、マクロ実行中に作成し作業終了後に削除する方法もあります。

目次へ

1.6 各種情報表示マクロ

マクロ作成時に使用しているマクロです。"内部的な値を表現するキーワード"を新規秀丸エディタに出力します。

• 情報表示マクロ Ver.8.99対応版　[2021/10/02版]

情報表示出力サンプル

「ファイルタイプ別の設定」の詳細(config文で指定できる物)

• ファイルタイプ別の設定表示マクロ Ver.8対応版　[2011/05/02版] ファイルタイプ別の設定出力サンプル

目次へ

1.7 ファイル保存時のフォルダ指定

「ファイルの保存」ダイアログで、保存位置を任意のフォルダにする方法です。

//C:\TEMPをカレントにする例　ここから
$base = basename;
$name = filename2;
//保存フォルダ指定　最期に"\\"を付けること
$savefolder = "C:\\TEMP\\";
//更新されているかどうかのフラグ
#update_flg = updated;

//保存先のフォルダをベースに名前を変更
changename $savefolder + $base;
//saveダイアログ表示
SAVEAS;
if(!result){
    //キャンセルした場合はファイル名を元に戻す。
    changename $name;
    //何も編集していない状態でも（更新）になってしまうのでフラグをみて強引に解除。
    if(#update_flg == 0) clearupdated;
}
//ここまで

「SAVEAS」は編集中のファイルのあるフォルダを開くので、ファイル名を保存したいフォルダに変更してから「SAVEAS」を実行。

目次へ

1.8 ファイルを開くときのフォルダ指定

「ファイルを開く」ダイアログで、開く位置を任意のフォルダにする方法です。

制限はありますが、動作環境で指定することも可能です。 ([HMEXXXXA]●ファイルを開く場合、最初に開く場所を指定したいを参照)

openfile "C:\\TEMP\\*.txt"；

$folder = hidemarudir;
#main = hidemaruhandle(0);
//ダミーの秀丸エディタを非表示(ステルス)状態で開く。
//openfile "/n /h " + $folder + "\\dummy" + filetype;
//秀丸エディタを非表示(ステルス)状態で、フォルダを指定して開く。
openfile "/n /h /d " + $folder;
#sub = hidemaruhandle(0);
OPEN;
//「キャンセル」の場合はマクロを起動した秀丸エディタに制御を戻す。
//「開く」の場合は開く秀丸エディタに制御が移るので問題ない。
if(!result) setactivehidemaru #main;
//ダミーの秀丸エディタを閉じる。(自分自身は無効)
closehidemaruforced #sub;
//マクロ終了時に表示されるはずだが、念のため。
showwindow 1;

//フォルダの設定
$opendir = "C:\\";
//シェルオブジェクトの作成
#n = createobject("WScript.Shell");
if(#n == 0){
    message "オブジェクトの作成に失敗しました。";
    endmacro;
}
//カレントフォルダの変更
setpropstr #n, "CurrentDirectory", $opendir;
if(!result){
    message "カレントディレクトリの変更に失敗しました。";
}
//ファイルを開く
OPEN;
endmacro;

1.9 webブラウズモード関連

2009/09/23

hideHidemarnet Explorerの設定を変更

Hidemarnet Explorer関連。

if(filetype == "webbrowse")

if(strstr(basename,"http://") == 0)

if(strstr(basename,"http://") == 0 && strstr(basename,"https://") == 0)

if(basename == filename)

if(basename == filename && strstr(basename,"http") == 0))

if(basename == filename && strstr(basename,"://") != -1))

$title = gettext(0, 0, 255, 0);
if($title == ""){
    $title = "No Title";
}

//カーソルを移動し、必要な長さだけ取得する方法
//マクロ起動時のカーソル位置保存
#x = x;
#y = y;
//先頭に移動
moveto 0,0;
$title = gettext(0, 0, linelen2, 0);
if($title == ""){
    $title = "No Title";
}
moveto #x, #y;

<a href="https://hide.maruo.co.jp/">『 秀まるおのホームページへ 』</a>

[xx:『 秀まるおのホームページへ 』.] 

xx:https://hide.maruo.co.jp/

searchup "(?<=\\[)[0-9]+?:", regular;

<a href="https://hide.maruo.co.jp/">『 秀まるおのホームページへ 』</a>

[a:https://hide.maruo.co.jp/]『 秀まるおのホームページへ 』

searchup "(?<=\\[a:)[^\\]]+",regular;

1.10 webブラウザ関連

2024/09/24　PowerShellから「UI Automation」を使う方法を修正

webブラウザのメモ。識別に必要なウィンドウクラス名とDDEサービス名などいろいろ。

ブラウザによっては、ウィンドウクラス名だと識別はできない。どうしても識別したい場合は、ウィンドウハンドルから実行ファイル名を調べるか、ウィンドウのキャプションから判断する。（自分でDLLを作らないと無理。）

ブラウザの資料？（DDE通信）

ブラウザの資料？（COM/OLE）

• サポートしているコマンドは各自で調べること。

  • Operaは、正式には"WWW_OpenURL"しか対応していないが、その他も動作するらしい。

• Sleipnir はウィンドウクラス名では検索できない。(Ver 1.66の場合)

  そのまま起動してしまえばだいたいタブに追加される。（Sleipnir側の設定による）

• Mozilla、Netscape7、Firefox で新しいタブで開く方法

  コマンドはないので(デフォルトでは) "Ctrl+T" を送り、新しいタブを開かせてからDDE通信を行えばいい。キーの送信は秀丸エディタでは出来ないので、外部ツールかDLLを使うしかない。各種拡張でDDE通信からでもタブで開けるようにすることも可能。

  Firefoxはどのバージョンから有効なのかわからないが、コマンドラインオプションが追加されている。

  • URLを新しいタブで開く　Firefox.exe -new-tab URL1 -new-tab URL2
  • URLを新しいウィンドウで開く　firefox.exe -new-window URL

• Mozilla、Netscape7、Firefox の　WWW_GetWindowInfoコマンド

  英数字はいいけど、２バイト文字は化けます。キャラクタコードを見るとUnicodeの下位バイト？

  • 2007/01/08現在　Firefoxは修正されている。
  • Mozillaは開発終了。Seamonkeyへ。

• ブラウザと連携するのは関連づけ起動を使うのが簡単ですが、htmlファイルをwebブラウザで表示しようとすると、常に新しいwebブラウザが起動してしまう場合があります。これはDDEの設定が行われていないか、DDEを使わないようにしている場合だと思います。

  • IEの場合、DDEが有効でも、常に新規に開くように設定で変更可能。起動オプションに"-new"をつけると、新規に開くことが出来ます。まぁ、単純に起動すれば、だいたい複数起動しますが。

ブラウザとDDE通信をするためのサンプル。クラス名、ファイルパス、サービス名、URLを入れれば動くと思う。

//ブラウザを確認するためのウィンドウクラス名
$ClassName = "";
//起動するためのファイルパス
$Program = "";
//DDE通信で使うサービス名
$DDEName = "";
//Profileを使い分けている場合は使用するプロファイル名を指定
// Mozilla,Firefox,Netscapeのみ
$Profile = " -P \"prifilename\"";
//アドレスの指定
$URL = "開きたいアドレス";

#ret = findwindowclass($ClassName);
if( #ret == 0 ) {
    //ブラウザが見つからないので起動する。
    run "\""+ $Program + "\"" + $Profile;
}
//ブラウザが見つかったのでDDE通信でURLを渡す。
ddeinitiate $DDEName, "WWW_OpenURL";
if( !result ){
    message "DDEの初期化に失敗しました。";
    ddeterminate;
    endmacro;
}
$ret = dderequest($URL + ",,0xFFFFFFFF,0x1,,,");
if( !result ){
    message "DDEコマンドが失敗しました。";
}
ddeterminate;
endmacro;

• "WWW_OpenURL"について

  以下の内容は、Netscape(おそらくはVer.4.xxのころ)の仕様を元に書いています。その為、IE、Opera、Mozilla、Firefoxでは動作が違う場合があります。

  webブラウザに対してURLを送り、指定したURL開かせる命令です。引数はいくつかありますが、

  • 開くURLを示す第一引数
  • ウィンドウを指定する第三引数
  • フラグである第4引数

  が、主な引数になります。

  第三引数は開くウィンドウを示し、本来ならWindowIDを指定しますが、 0xFFFFFFFFを指定することにより、最期にアクティブだったウィンドウで開きます。 (ちなみにFirefoxの場合、""を指定すると（設定や拡張にもよりますが）新しいウィンドウで開きます。)

  第四引数はキャッシュ等のフラグです。

  • 0x1はドキュメントキャッシュを無視します。
  • 0x2はイメージキャッシュを無視します。

  ORで指定できるので、0x3でドキュメント、イメージのキャッシュを使用しないという意味になります。

• ブラウザのコントロール

  タブ・ブラウサを使用している場合、新しいタブで開きたいとか、表示しているタブで開きたいなど、要望があるかも知れませんが、これはかなり難しいです。

  • mozilla系(firefox、Netscapeも含む)
    そもそも、外部からコントロールするためのインタフェースがない。 DDE通信で開く場合も、ブラウザ本体の設定及び、各種拡張機能の設定によるので、どうなるかはわかりません。
  • タブ・ブラウザ系
    Sleipnir、Lunascape等のブラウザはWSH(Windows Script Host)による制御が可能です。（外部から操作できる状態にするので、セキュリティ的にはよろしくない。）その為、やりたいことをWSHで書いて、引数でURLを渡した方が、細かく制御できます。
    • macrodll.dll(Ver.0.81)を使用すれば、秀丸エディタからでも直接制御が可能です。
  • IE7,8について
    IE7,8の場合、OSよって、挙動が異なります。XPの場合、タブで開きたい場合は、面倒な処理が必要です(Vistaでは、IE6と同じ方法で簡単にタブで開ける)。 Windows Vistaの場合、IEのオブジェクトを操作時にエラーになる場合があります。これは、IEの「保護モード」が有効になっているためです。「保護モード」を有効にしたまま、IEのオブジェクトを操作するには、 "Shell.Application"を使用します。
    WSHでIE7,8を制御する方法は、以下のwebサイトが参考になります。
    • 7.1 IEオブジェクトを作る(～IE6編)(2016/09/06現在アクセス不可)

• Firefoxメモ

  • Firefoxのウィンドウクラス名
    ウィンドウクラス名は、ブラウザウィンドウだけではなく、以下のウィンドウも同じクラス名を使用している。その為、ウィンドウクラス名だけでは、ブラウザが起動しているか確実な判断はできません。

    • ダウンロードマネージャ
    • アドオン
    • 履歴とブックマークの管理
    • エラーコンソール
    • ソース表示
    • ページ情報

  • 起動オプションの"-new-tab"を使う場合の注意
    "-new-tab"を指定し、タブを追加するには、ブラウザウィンドウが起動している必要がある。起動していないと、"-new-window"を指定したように、新しいウィンドウが開き表示される。

  • マルチプロセス機能(e10s) を有効にしていると、DDE通信が失敗する。(確認したのは Nightly 51.01a 2016/09/19) Firefox 57.0 から、マルチプロセス機能(e10s)がデフォルトで有効化されています。

    その為、DDE通信が正常に動作しないものもあります。

    • WWW_GetWindowInfo は動作しない。
    • WWW_OpenURL は動作する。

  • Firefox 70.0.1 だと DDE通信自体が使用できない。(Firefox 67から？)

• Microsoft Edge メモ

  • ウィンドウクラス名は、"ApplicationFrameWindow" になるが、ストアアプリは全部"ApplicationFrameWindow" なので、ウィンドウクラス名だけでは判断できない。「Edge」の実体は、"TabWindowClass"になるので、こちらで判断する方がいい。

    Microsoft Edge(Chromium版)は、「Google Chrome」と同じ「Chrome_WidgetWin_1」なので、ウィンドウクラス名でブラウザを識別できない。

  • 関連づけが「Edge」の場合は、関連づけ起動を行えばいいが、違う場合はストアアプリである「Edge」を起動するのは、非常に面倒です。

    URLの場合は、URI スキーム名 "microsoft-edge:" を使うのが簡単です。

    microsoft-edge:https://hide.maruo.co.jp/

    URLの先頭に"microsoft-edge:"を追加し、関連づけ起動を行います。

    ローカルファイルの場合は、"microsoft-edge:"を指定しても、開くことは出来ない。 (file:///～ と言う形式で指定してもローカルファイルは開かない)

    ストアアプリは以下の方法から起動可能なので、引数にローカルファイルを指定すればいい。

    shell:AppsFolder\<PackageFamilyName>!<ApplicationId> 

    「PackageFamilyName」と「ApplicationId」はショートカットから読み取れるし、VBS、PowerShellのスクリプトで調査可能。

    コマンドプロンプトからは以下のコマンドでローカルファイルを開くことが出来る。

    start shell:AppsFolder\Microsoft.MicrosoftEdge_8wekyb3d8bbwe!MicrosoftEdge ローカルファイルパス

    "start" がないと開かないので関連づけ起動している。

    WSHのWshShellオブジェクトを使うと、関連づけ起動が可能なので、WSH(VBS)の場合は、以下のスクリプトでURLやローカルファイルをEdgeで開くことが出来る。

    Option Explicit
    
    Dim WshShell
    Dim WshArgs
    
    Set WshArgs = WScript.Arguments
    
    if WshArgs.Count > 0 then
        Set WshShell = CreateObject("WScript.Shell")
        WshShell.Run "shell:AppsFolder\Microsoft.MicrosoftEdge_8wekyb3d8bbwe!MicrosoftEdge " & WshArgs.Item(0)
        Set WshShell = Nothing
    End if
    Set WshArgs = Nothing
    
    WScript.Quit 0

    上記スクリプトをベースにすれば、秀丸マクロからEdgeを呼び出す事が可能。

    秀丸エディタからは、「openbyshell文」で関連づけ起動が可能ですが、 Ver.8.77までは、"microsoft-edge:～"や、"shell:AppsFolder～"を指定しても、関連づけ起動できません。これは 秀丸エディタ Ver.8.79 で修正されます。

    Microsoft Edge(Chromium版)は、デスクトップアプリなので、実行ファイルの場所さえわかれば、起動可能です。

  • Microsoft Edge(Chromium版) でも「URI スキーム名」は有効(Ver.83.0.478.56で確認)。「UI Automation」から見た構成は、「Google Chrome」とかなり異なり、取得できる情報も違いがある。各コントロールにクラス名が付いているので、検索はしやすいかもしれない。

• 「UI Automation」を使ってwebブラウザから情報を取得する方法

  Windows10で動作する主要なWebブラウザ(Google Chrome、Firefox、Edge)は、DDE通信は使えない。

  起動中のブラウザから情報を取得するには、「UI Automation」を使う方法があるが、ブラウザ毎に取得方法が異なるし同じブラウザでも、バージョンによって異なる場合もある。

  秀丸マクロで直接「UI Automation」を扱うことは無理なので、別の言語を使う必要がある。

  「UI Automation」を使って情報を取得するには各アプリケーションの構造を調べる必要がある。構造を調べるには「Inspect (Inspect.exe)」を使う。

  AutoIt3 + UIASPY を使って、Google Chrome(Ver.101.0.4951.54)、Firefox(Nightly 102.0a1)、Edge(Ver.101.0.1210.39) を対象に以下の動作をさせてみた。

  • 表示しているページのタイトルとURLを取得
  • 指定されたURLを開く、ただした別のタブで開いていた場合は、アクティブにして更新

  「表示しているページのタイトルとURLを取得」は、URL入力用エディットボックスから「URL」を取得できるが、アドレスと検索入力欄が同じコントロールなので、場合によってはURLを取得できない。また、URLの先頭にプロトコル("http://" or "https://")が付かない場合もある。タイトルも、ウィンドウのタイトルバーから取得できるが、最後にブラウザ名が付いてくる。確実に表示しているページの「URL」と「タイトル」を取得するには、各情報をもつコントロールを見つけて、プロパティを取得する必要がある。

  「指定されたURLを開く」場合は、「URL」の入力欄を書き換える必要がある。 Firefoxの場合、「UI Automation」 から書き換えが出来ないので、文字列を送信するしかないが、IMEの状態も確認が必要。 Firefox、Chrome 、Edge は「UI Automation」から書き換え・設定可能だが、最終的には「リターンキー」を送信する必要がある。 (「リターンキー」以外の方法があるかまでは未調査) その為、タブは増えてしまうが、「URL」を引数にwebブラウザを呼び出すのが一番簡単。

  「開いている全てのタブ」の情報を取得するのは、Firefoxがやりやすい。タブを切り替えなくても「URL」、「タイトル」を取得できる。 Chrome と Edge は「タイトル」は取得可能だが、「URL」を取得するには、タブを切り替える必要がある。

  「更新」させるのは、「UI Automation」で更新を行うボタンを取得できれば簡単にできる。

  • PowerShell

    PowerShell から「UI Automation」を使っても、ブラウザによっては「Inspect (Inspect.exe)」で確認した内容と違う結果になります。

    • Microsoft Edge(Chromium版) は PowerShell スクリプトだけで各種情報を取得可能。
    • Google Chrome や Firefox は PowerShell スクリプトだとうまくいかない。 (メインウィンドウ直下の子ウィンドウの取得がうまくいかない、プロパティ値が取得できない等)

    原因はよくわかりませんが、Microsoft Edge(Chromium版) だと問題ないので、アプリケーション側の問題かもしれない。

    Google Chrome や Firefox の場合はPowerShellスクリプトから C# で「UI Automation」部分を直接記述するようにしてください。 C#からも「Inspect (Inspect.exe)」と同じ内容が取得できないので、「FlaUI」等のライブラリを使った方がいいでしょう。 (拡張機能無しの、C#・PowerShell からだとどうしてもうまくいかない)

目次へ

1.11 キー操作の記録

マクロ作成時、秀丸エディタの機能でどのコマンドを使っていいのかわからない場合は「キー操作の記録」を使います。キー操作の記録を開始し、使いたい機能を実行して記録を停止。「キー操作の保存」でファイルに保存できるので、適当な名前をつけて保存し秀丸エディタで開けばコマンドがわかります。

[注意]

• 全ての機能を記録できるわけではありません。記録されないコマンドもあります。

目次へ

1.12 カーソル移動コマンドの注意点

update：2014/03/29 確認用マクロを変更し説明用画像を追加

ここでの カーソル移動コマンド とは、moveto、movetolineno goline～ のコマンドの事です。

選択モードを終了しても範囲選択状態でカーソル移動コマンドを使うと、移動した場所まで範囲選択状態になります。 (範囲選択が広がってしまう。)

確認用マクロ

//範囲選択開始
beginsel;
moveto x + 3, y;
//範囲選択モード解除
endsel;
message "範囲選択終了";
//範囲選択モードを解除したはずなのに移動したカーソル位置まで選択される。
moveto x + 3, y + 3;
message "カーソル移動";
endmacro;

動作的にはおかしいけど、現状（2004/05/22）においては仕様ということです。

範囲選択した後の操作（コマンド？）で範囲選択が解除されれば問題はないが、解除されない場合にカーソル移動を行うと思わぬ結果になるので注意。

この動作を回避するには、範囲選択終了後に、一度カーソルを動かせばいい。(left、right等)

目次へ

1.13 ループ中の負荷低減

田楽シリーズのVer.2.70 から、SLEEP関数が追加されています。

秀丸エディタVer.8.00 から、sleep文が追加されています。

マクロでループ処理を行うとCPUを使い切ってしまいます。 NT系OSだとまだいいのですが、Windows9x系だと固まったように見えたりします。そこでWSHを使ったCPU負荷の低減の方法です。（WSHを使うので Windows 98 以降が必要。）

以下の内容を"sleep.vbs"として保存します。

'100mS停止するvbs
Wscript.Sleep 100

"sleep.vbs"　をrunsync2 で呼び出せばOKです。

call WaitMillisecond1 10000;
call WaitMillisecond2 10000;
endmacro;
//サブルーチン本体
WaitMillisecond1:
    ##goaltime = tickcount + ##1; 
    while(##goaltime > tickcount); 
return; 

//サブルーチン本体
WaitMillisecond2:
    ##goaltime = tickcount + ##1; 
    while(##goaltime > tickcount){
        runsync2 "Wscript.exe " + currentmacrodirectory + "\\sleep.vbs";
    }
return;

秀丸担当氏によると、

裏技的に ddewaitadvice "",1000; などとすればCPUを食わずに待つこともできてしまいますが
（秀丸エディタβ版＆秀丸メール常連さんフォーラム秀丸エディタβ版会議室　07627より引用）

という方法もあるとのことです。しかし、DDE通信は秀丸エディタを切り換えると自動的に終了するので、秀丸エディタを切り換えるようなマクロでは、たぶん使用できません。

目次へ

1.14 ウィンドウ一覧のタブのon／off

秀丸エディタ Ver5.00β27より"settabmode"コマンドが追加された為、レジストリ操作は必要なし。

目次へ

1.15 任意部分のレジストリデータ列挙

reg.exeを使う方法を追加

マクロでレジストリの読み込みは出来ますが場所がわかっていないと駄目です。つまり、任意部分の値を列挙することは出来ません。

そこで OS に付属されている regedit.exe を使ったレジストリ値の列挙方法を紹介します。方法はいたって単純で、レジストリデータのエクスポート機能を使うだけです。

注意 Windows Vista以降、UAC(ユーザー・アカウント制御)が有効な場合、権限の昇格が必要な為、マクロからレジストリエディタを起動しようとしても、失敗します。

レジストリエディタのエクスポート方法

regedit /e /a 出力ファイル名 レジストリの場所

/e エクスポート処理
/a ASCIIコードで出力(NT系は デフォルトでユニコード)

これで指定したファイルにレジストリデータがテキスト形式で出力されるので、これを解析します。 (grepを使うのがいいでしょう。)

注意事項としては指定されたレジストリデータ全てを出力するので、指定した場所によっては、ファイルが巨大になる可能性があります。

reg.exe のエクスポート方法

reg.exe export レジストリの場所 出力ファイル名 /y

/y 確認なしで、出力フィルを上書きする。

詳細は、コマンドプロンプトから「reg.exe export /?」と入力し表示されるヘルプを参照してください。

1.16 マクロから呼び出すWSH

2009/11/03

Ver.8より、追加されたコマンドに注記を追加。

マクロから呼び出すと、役に立つかもしれないScript各種？ WSHは全部VBScriptです。

• 実行するスクリプトファイルは、必ずフルパスで指定してください。（スクリプトファイルが、カレントフォルダにある場合は不要です。）
• run/runsync/runsync2 文を使って実行してください。

//10秒待機する
runsync2 "wscript.exe " + currentmacrodirectory + "\\sleep_sec.vbs 10";

Wscript.exe Tk_MakeShortCut.vbs "対象ファイル/フォルダ" "ショートカットのフルパス"

Wscript.exe fileutil.vbs cmd file1 file2

Wscript.exe CallIE.vbs URL1 URL2 …

1.17 ダイアログを表示してファイル名を取得する

2023/04/10

browsefile関数の説明を追記

2019/09/29

リンクを追加

関連項目

• browsefile関数
• ファイル選択ダイアログ

秀丸エディタ Ver.9.16 以降「browsefile関数」が使用できます。関数には初期フォルダとワイルドカードを指定します。複数ファイルの選択はできません。

マクロでファイル選択ダイアログを使ってファイル名を取得する方法です。田楽DLLを使えばコマンドは用意されていますが、これだけのためにDLLを使うのも面倒です。（この方法も十分面倒かもしれませんが・・・）

やっていることは単純で、非表示で開いてfilenameキーワードから取得しているだけ。

複数ファイルを選択した場合は、うまく動きません。レジストリを操作して、複数選択を出来ないようする方法もあります。 (レジストリを操作する場所は「開く」のダイアログボックスを参照。)

//起動した秀丸エディタのハンドルを取得
#main = hidemaruhandle(0);
//最初に開くフォルダの指定
$dir = macrodir;
//最初に表示する拡張子の指定
$ext = "*.mac";
//非表示状態で秀丸エディタを開く(ステルス秀丸)
//ワイルドカード($ext = "*.mac")を指定しているので、
//"ファイを開くダイアログ"が表示される。
openfile "/h " + $dir + "\\" + $ext;
//選択した秀丸エディタのハンドルを取得
#sub = hidemaruhandle(0);
//ファイル名を取得
//ファイルを選択した場合は、ファイルを(非表示のまま)開いているので、
//ファイル名を取得できる。
//キャンセルした場合は、新規ファイル(無題・新規ファイル)になるので、
//ファイル名は""となる。
$target = filename;
//マクロを起動した秀丸エディタに戻り、開いたファイルを(強制的に)閉じる
setactivehidemaru #main;
closehidemaruforced #sub;

//判定
if($target != ""){
    message $target + "を選択しました。";
}else{
    message "キャンセルされました。";
}

endmacro;

• 起動オプションには"/n"を追加し、履歴に残さないほうがいいかも。
• "/b"を追加しておけば".exe"、".com"、"*.dll"など選択しても「変換出来ない・・・」の警告が出ません。
• 「開く／キャンセル」の判定に"result"を使用していないのは"/h"を使用している為です。
  "/h"を指定した場合、resultは常に"1"を返します。（秀丸エディタの仕様　hidesoft.2:17947参照）

目次へ

1.18 秀丸エディタのレジストリデータ

A:保存するファイルが空だったときは確認する
B:無題で更新されていて、内容が空のとき、保存するかどうか確認する
C:"DeleteAtNull"の値
 B│ A│ C
─┼─┼─
 0│ 1│ 3
 0│ 0│ 2
 1│ 1│ 1
 1│ 0│ 0
1:チェックあり
0:チェックなし

0:問い合わせる
1:上書き禁止
2:じファイルを２つ開くことを禁止する。
3:ファイルを読み直しする

0x0a:旧タイプ
0x0b:旧タイプ（複数選択タイプ）
0x0c:Windows3.1タイプ
0x0d:Windows95タイプ
0x0e:Windows95タイプ（複数選択タイプ）
0x0f:Windows2000タイプ
0x10:Windows2000タイプ（複数選択タイプ）
0x11:WindowsVistaタイプ
0x12:WindowsVistaタイプ（複数選択タイプ）
0x0d:秀丸ファイラーclassic
0x10:秀丸ファイラーclassic（複数選択タイプ）

0x01:秀丸ファイラーclassic チェックなし
0x03:秀丸ファイラーclassic チェックあり

0x00000001:タブモード有効
0x00000002:[デザイン]「ボタン型」がON
0x00000004:[デザイン]「ウィンドウ右上の閉じる(×)ボタンでタブを全て閉じる」がOFF
0x00000008:[デザイン]「２つ以上開いているとき、・・・・」がOFF
0x00000010:[デザイン]「タブバーの右端に小さな閉じる(×)ボタンを表示」がOFF
0x00000020:[配　　置]「閉じた後にアクティブにするタブ」が「左のタブ」
0x00000040:[配　　置]「閉じた後にアクティブにするタブ」が「右のタブ」
0x00000100:[配　　置]「新しいタブの位置」が「左端に追加」
0x00000200:[配　　置]「新しいタブの位置」が「右に挿入」
0x00000300:[配　　置]「新しいタブの位置」が「左に挿入」
0x00000800:[デザイン]「ウィンドウ幅からはみ出すとき」が「スクロール」
0x00008800:[デザイン]「ウィンドウ幅からはみ出すとき」が「複数段」
0x00001000:[デザイン]「アイコン表示」がOFF
0x00002000:[配　　置]「外部から起動するとき」が「前面の秀丸エディタにタブを追加」
0x00004000:[配　　置]「外部から起動するとき」が「常に新しいウィンドウ」
0x00XX0000:[デザイン]「幅を固定」のサイズ(0～255　0x00～0xFF)
0x01000000:[デザイン]「確認する」がON
0x02000000:[デザイン]「タブごとの閉じるボタン」が「右側に閉じるボタン(自動)」
0x04000000:[デザイン]「タブごとの閉じるボタン」が「アイコンを閉じるに(常に)」
0x10000000:[デザイン]「タブバーの位置」が下
0x20000000:[デザイン]「タブバーの位置」が非表示

0:普通タイプ
1:新タイプその２（フォルダ選択は旧式のまま）
2:新タイプ（フォルダ選択がエクスプローラ風）

0x0:左
0x1:右
0x2:上
0x3:下
0x1:浮かせる(Detailの値が0x1になる)

0x1:浮かせる(Rightの値が0x1になる)
0x2:枠の表示でウィンドウサイズを広げる
0x4:一覧の選択時にカーソルを上のほうに移動する
0x8:ドラッグ＆ドロップ編集を可能にする

DLL:32bit DLLをマクロのloaddllで動作可能にする
HMF:32bit 変換モジュール(*.hmf)を動作可能にする
X64:X64の値

HMF │DLL │X64 
──┼──┼──
   0│   0│ 0x00
   0│   1│ 0x01
   1│   0│ 0x02
   1│   1│ 0x03
1:チェックあり
0:チェックなし

"HKEY_CURRENT_USER\SOFTWARE\Hidemaruo\Hidemaru\Hidemaruo_Sort_Org" の"Parameter"

1.19 openfileについて

2009/09/26 ワイルドカードについて追記

openfileコマンドだけでなく秀丸エディタ本体の起動オプションにも関係があります。

openfileコマンドでファイルを指定する場合、空白を含むパスでも""で囲む必要はありません。しかし、複数ファイルを指定する場合は注意が必要です。

カレントフォルダにあるファイルを開く場合はフルパスを指定しなくても開きます。

ex)openfile "a.txt"; //a.txtを開く

カレントフォルダにある複数のファイルを指定すると、１つのファイルと見なされます。 (空白を含むパスでも開けるようにした為の副作用)

ex)openfile "a.txt b.txt"; //a.txtとb.txtを開く
実際は "a.txt b.txt" という新規ファイル扱いとなる。

この問題を回避するにはフルパスで指定するか、ファイル名を""で囲みます。（ファイルの区切りを明確にする。）

秀丸エディタ本体の起動オプション指定時も同じなので、バッチファイルで使う場合は注意が必要です。

hidemaru.exe %1 %2 %3 %4 %5 %6 %7 %8 %9

というバッチファイルの場合、ファイル指定時に""で囲まないと指定した名前をすべて結合した新規ファイルと認識されます。（ファイル名をフルパスで指定すれば問題ない）

ちなみに、バッチファイルの内容を、

hidemaru.exe "%1" "%2" "%3" "%4" "%5" "%6" "%7" "%8" "%9"

とすると、ファイル指定がなくても９個の秀丸エディタが開いてしまいます。

NT系OSの場合は

hidemaru.exe %~f1 %~f2 %~f3 %~f4 %~f5 %~f6 %~f7 %~f8 %~f9

とすると、引数がフルパスに変換されて渡されるので問題ありません。

opnefileには、ワイルドカードも指定可能です。ワイルドカードを指定すると、指定されたフォルダを「ファイルを開くダイアログ」で開き、指定された拡張子のファイルを表示します。

例) openfile macrodir + "\\*mac";

ワイルドカードを指定する場合は、ダブルクォート「"」で、囲まないこと。 ( turukame.3:03948, turukame.3:05864 を参照)

目次へ

1.20 URLエンコードとrun

秀丸エディタから、webの検索サービスを使用し、検索する場合には注意が必要です。

検索サービスで日本語を扱う場合、検索文字列をURLエンコードしブラウサに渡す必要があります。検索文字を渡す方法がDDE通信なら問題ありませんが、run文で起動オプションとして渡す場合、 %b、%d、%f が含まれていないか確認する必要があります。

%b、%d、%f はプログラム実行の詳細の所に説明がありますが、

%b:フォルダを除いたファイル名(basenameキーワードと同じ)
%d:フォルダ名(directoryキーワードと同じ)
%f:フルパスのファイル名(filenameキーワードと同じ)

という意味を持ってます。その為、URLエンコードした文字列の中に%f1、%b2、%b3 などがある場合、それぞれフォルダ名等に変換されてしまい、正しい検索ができません。ちなみに大文字、小文字は無視されるので、%B、%D、%F でも同じです。

例）引数を表示するvbsを実行した結果

//テストマクロ
$base = "原因究明";
#len = strlen($base);
#cnt = 0;
$out = "";
while(#cnt<#len){
    $ret = hex(ascii(midstr($base, #cnt, 1)));
    //２バイト文字の範囲は0xXX00と変換されるので補正
    if(strlen($ret) > 2) $ret = leftstr($ret, 2);
    $out = $out + "%" + $ret;
    #cnt = #cnt + 1;
}
run "Wscript.exe " + macrodir + "\\argv.vbs " + $out;
endmacro;

検索文字　：原因究明
エンコード：%8C%B4%88%F6%8B%86%96%BE
ファイル名：C:\temp\test.mac

vbsに渡された文字列：%8Ctest.mac4%88C:\TEMP\test.mac6%8B%86%96test.macE
　                   %8C%B      4%88%F              6%8B%86%96%B      E
　                      ==          ==                        ==

これを防ぐには、%f --> %%f のように%%とするか、ブラウザを起動してからDDE通信でわたします。

秀丸エディタVer.6.50β11より、openbyshell文に、引数が渡せるようになったので、こちらを使った方がいいかもしれません。

目次へ

1.21 「検索での表示」の違いを吸収する

秀丸エディタの「動作環境」->「検索」->「検索での表示」には「点滅表示」と「範囲選択」の２つがあります。マクロでは「範囲選択」に設定されているほうがいろいろと便利なので、「範囲選択」に設定されていることを期待している場合が多いです。マクロ起動時に秀丸エディタ本体の設定を書き換え、終了後に戻すマクロもあります。

秀丸エディタ Ver.4.10から追加された「foundtopx, foundtopy, foundendx, foundendy」のキーワードを使うと、秀丸エディタ本体の設定を書き換えずに「点滅表示」でも「範囲選択」と同様に選択された状態にすることが出来ます。

searchdown2 "検索文字";
if(result){
    //「検索での表示」が「点滅」になっている場合の処理
    //「範囲選択」なら選択状態になっている --> selectline キーワード
    //「検索での表示」の状態               --> searchmode キーワード
    // searchmode だけでいいかもしれない・・・。
    if(!selecting && !searchmode){
        //マッチした範囲を選択状態にする。
        moveto foundendx, foundendy;
        beginsel;
        moveto foundtopx, foundtopy;
        endsel;
    }
}

秀丸エディタ Ver.6.00から追加された「setcompatiblemode文」を使えば、レジストリ操作なしで、マクロ実行時のみ設定を変更することが可能です。

目次へ

1.22 「検索文字列の強調」関連

秀丸エディタ Ver.5.00で検索文字列の強調表示ができるようになりました。その為、マクロで検索を使っていると検索した文字列が強調表示されてしまいます。

検索時に強調表示を行うかどうかは、searchoptionのビット11(検索、grep)、ビット12(置換)で設定できます。強調表示したくない場合は、このビットをマスクしてから検索・置換を実行します。ただし、検索・置換時の設定まで影響を受けるのでマクロ終了時に元の値に戻す必要があります。既存(秀丸エディタ Ver.5未対応)のマクロを使うと強調表示されないように設定される場合が多いです。

秀丸エディタ Ver.5.00β10 から変更があり、setsearchでビット11、12を変更する場合はビット13を"1"に指定しないと機能しないようになりました。この変更はVer.5に対応していないマクロを使用した場合に強調表示の設定が変更できないようにするための処置です。
searchoption は常にビット13がセットされているとのことなので、searchoptionの値をマスクして使う場合は気にする必要がありません。値を直にセットする場合は注意する必要があります。

• 強調表示する場合　：置換時　0x3XXXX　検索時　0x28XX
• 強調表示しない場合：置換時　0x2XXXX　検索時　0x20XX

秀丸エディタ Ver.5.00β12 から変更があり、searchdown等のオプションに"hilight"、"nohilight" が追加されました。 searchoption と違い、秀丸エディタ本体側の設定とは切り離されているとのこと。

$BAK_SEARCHBUFFER = searchbuffer;
#BAK_SEARCHOPTION = searchoption;
//検索時の強調表示の取り消し
setsearch $BAK_SEARCHBUFFER, (#BAK_SEARCHOPTION & 0xF7FF);
searchdown2 "・・・・", regular;
＜処理をいろいろ＞
//元の設定に戻す。
setsearch $BAK_SEARCHBUFFER, #BAK_SEARCHOPTION;

目次へ

1.23 ウィンドウの分割について

秀丸エディタ Ver.8.54β4 からマクロを使用する事で、分割位置を指定して分割できるようになりました。

split #splitmode, 1, 分割位置

(詳細は、マクロヘルプのsplit文 を参照のこと。)

また、秀丸エディタ Ver.8.54β6から、splitposキーワードが追加になり、分割位置を取得可能になりました。

マクロを使用する必要はありますが、分割位置を指定して分割する事も、分割位置をキーボードで変更する事も可能になっています。分割位置を変更するには、分割を解除する必要は無く、そのまま split文 で分割位置を指定して分割すれば可能です。

//現在の高さ保存
#baseHight = windowheight;
setwindowsize windowwidth,(windowheight/(1 + 2)) * (1 + 1);
split;
setwindowsize windowwidth,#baseHight;

1.24 割り当て可能なキーの一覧

割り当て可能なキーの一覧です。秀丸エディタ Ver.5からキーカスタマイズが大幅に強化され、いままで割り当てができなかったキーが使用できるようになりました。

「キー割り当て拡張」関連のマクロ開発で必要になったので作ってみました。

• Ver.5以降
• Ver.4

目次へ

1.25 hmjre.dllのバージョン情報取得

hmjre.dllのバージョン情報を秀丸エディタと同じ形式で取得する方法です。

• Ver.5 --> 500

• Ver.4.16 --> 416

  message str(val(hex(dllfunc("JreGetVersion") & 0xFFFF))); #hmjre_ver = val(hex(dllfunc("JreGetVersion") & 0xFFFF));

10進数の範囲内でバージョン表記されている限りは大丈夫・・・。 16進数になった場合はヘルプの方法を使いましょう。

目次へ

1.26 タブ関連メモ

2010/04/14

最小化した状態からタブを分離した場合を追加

"ウィンドウのタブモード"関連のメモ

＜注意＞　秀丸エディタ Ver.5.00β31から各種タブ関連のマクロが追加されたため、各種キーワードを取得すればできるものもあります。

//".log"のみ分離する
#max = hidemarucount;
#cnt = 0;
#gr = -1;
while(#cnt < #max){
    if(filetype[#cnt] == ".log"){
        #handle = hidemaruhandle(#cnt);
        settabgroup #cnt, #gr;
        if(#gr == -1) #gr = tabgroup[#handle];
    }
    #cnt = #cnt + 1;
}

例)tabtotal[#cnt]

1.26.6 最小化した状態からタブを分離した場合

showwindow 2;
settabgroup hidemaruhandle(0), -1;
endmacro;

最小化した状態から分離したタブは、ウィンドウサイズが、通常サイズではなく、小さくなった状態で分離される。分離する場合には、通常ウィンドウに戻してから、分離すること。

目次へ

1.27 日本語を含むファイル名の分解時の注意

日本語を含むフルパスから、ファイル名とフォルダ名に分割する場合の注意点。

各フォルダの区切りは "\" です。その為、ファイル名とフォルダを分割する場合、最期の"\"を探す必要があります。

//フォルダ名を切り出す為、ファイル名の最期から1文字ずつ調べる。
$$target = "C:\\TEMP\\Dir1\\file1.txt";
##len = strlen($$target);
while(##len > 1){
  ##len = ##len - 1;
  if(midstr($$target, ##len, 1) == "\\"){
      //ファイル名分割処理
  }
}

これでも問題はありませんが、日本語を含む場合は注意が必要です。日本語(SJISコード)は２バイトで表現されますが、秀丸のmidstr関数は１バイト単位で処理します。その為、日本語の２バイト目が "\" と同じ0x5Cの場合でも、

if(midstr($$target, ##len, 1) == "\\"){

の条件に一致してしまい、誤動作してしまいます。

ファイル名が、"C:\TEMP\Dir1\file1表.txt"の場合
ファイル名：".txt"
フォルダ名："C:\TEMP\Dir1\file1表"
となってしまう。
表の文字コードは"0x955C"なので２バイト目の"0x5C"で誤検出する。

その為、日本語の第２バイトであるかどうかの判定が必要になります。

$$target = "C:\\TEMP\\Dir1\\file1.txt";
##len = strlen($$target);
while(##len > 1){
  ##len = ##len - 1;
  if(ascii(midstr($$target, ##len - 1, 1)) < 256 && midstr($$target, ##len, 1) == "\\"){
      //ファイル名分割処理
  }
}

「ascii(midstr($$target, ##len - 1, 1)) < 256」が判定コードになります。判定する文字の、１バイト前のASCIIコードが256(0xff)未満であるかどうかを確認しています。秀丸では漢字の上位バイトは"0x9500"のように最低でも"0x8100"以上をかえすので、それを利用して判定を行います。

Ver.8より、ascii関数の仕様が変更されています。その為、上記方法では、判定できなくなりますが、文字単位で処理する、wcsmidstr関数が追加されているので、そちらを使用します。 (２バイト文字の判定を参照)

hmjre.dllを使用した、フォルダ名、ファイル名の取得方法もあります。 DLLのページにある「hmjre.dllの使い方」を参照してください。

Ver.8.89β4 より、split関数が追加されています。split関数を使えば、マクロ関数のみでパスの分割が可能です。

$$target = @"C:\TEMP\Dir1\file1.txt";
//split関数は、配列のサイズを返す。
##len_max = split($path, $$target, "\\");
//ファイル名は最後になるので サイズから -1 の位置(ゼロスタートなので)
$$filename = $path[##len_max - 1];
// $$target から、$$filenameの長さ と、"\"の1文字文の長さをカット
$$dir = leftstr($$target, strlen($$target) - strlen($$filename) - 1);
message "$$target   = " + $$target + "\n" + 
        "$$filename = " + $$filename + "\n" +
        "$$dir      = " + $$dir;
endmacro;

目次へ

1.28 grepdialog、grepdialog2文について

秀丸エディタ Ver6.00β11より、grepdialog、grepdialog2で表示されるダイアログからキャンセルした場合、result が -2 になります。その為、以下の方法による「キャンセル」の判定は不要です。

if(result == 0 && filetype == "new"){
  //「キャンセル」した場合の処理
}else if(result == 0 && filetype == "grep"){
  //結果が"0"の場合の処理
}

$checktype = filetype;
#update = updated;
#handle = hidemaruhandle(0);
grepdialog2 "", "*.mac", macrodir, regular;
#ret = result;
if(#ret == 0 && (($checktype == "new" && #update == 0 && #handle == hidemaruhandle(0)) ||
                  #handle == hidemaruhandle(0))){
  //「キャンセル」した場合の処理
}else if(#ret == 0 && filetype == "grep" && #handle != hidemaruhandle(0)){
  //結果が"0"の場合の処理
}

1.29 versionキーワードを使う場合の注意

マクロを異なるバージョンの秀丸を動くようにするには、以下のようにversionキーワードを使います。

if(version >= 5.00){
  //Ver.5.00の処理
}else{
  //Ver.5.00未満の処理
}

しかし、"Ver.5.00の処理"内に、Ver.5.00で追加された命令、キーワードを使用した場合、 Ver.5.00未満ではエラーになり、実行できません。

これは、マクロの実行が、１行づつ変換・実行しているインタープリタ形式ではなく、コンパイル形式で実行されているからです。その為、実行する秀丸バージョンにない命令・キーワードが見つかると、コンパイル時にエラーとなります。

これを回避するには、完全に別のファイルにするしかありません。

if(version >= 5.00){
  //Ver.5.00の処理
  execmacro "ver5.mac";
}else{
  //Ver.5.00未満の処理
  execmacro "ver4.mac";
}

目次へ

1.30 チェックリストダイアログのベース

大本はIKKIさんが作成した「閉じるダイログ」です。「ファイルヒストリダイアログ」は、このベースから作成。

実行には田楽DLLが必要です。(要Ver.2.83) 拡張ソート機能を使うには、変換モジュールライブラリのソートが必要です。 Version 1.4.0 以降は秀丸エディタVer.8に対応したため、追加の変換モジュールは不要です。

• CheckListDialog.mac　[2012/12/24]

2006/01/08 Version 1.0.0

• 初版

2006/01/15 Version 1.1.0

• ソート機能を追加

2006/01/19 Version 1.2.0

• 田楽でもソートon/offができるようにした。

2006/01/19 Version 1.2.0

• 田楽でもソートon/offができるようにした。

2006/05/05 Version 1.2.1

• バグ修正
  • ソートモード0(ソートしない)が設定できなかった
  • 全選択が機能していなかった

2006/08/21 Version 1.3.0

• 初期表示でチェックの有無を指定出来るようにした。

2012/12/22 Version 1.4.0

• 秀丸エディタVer.8用に各部を修正

• 変換モジュールを使ったソートで、チェック状態を保持できる様にした。

• $ld_ListCheck が機能していなかったので修正。

• #ld_ListMax、 #ld_SelectCount、 #ld_DialogWidth、 #ld_CheckList[] を追加

  #ld_ListMax    ：入力用変数。表示リストの最大値を設定。
                   未設定(0)の場合は、$ld_ViewList[]が""まで読み込む。
  #ld_SelectCount：出力用変数。チェックした項目数を返す。
  #ld_DialogWidth：入力用変数。ダイアログ幅の設定。デフォルトで80。
  #ld_CheckList[]：入出力変数。
                   チェックの初期状態の設定入力および、チェック結果を格納する。
                   0でチェックなし、１でチェックあり。

• 変換モジュールのソートで、ステルス秀丸を使わない様にした。

• #ld_CheckList[]にも、結果を戻す様にした。

2012/12/24 Version 1.4.1

• ソートなしが、設定できなくなっていたバグの修正。
• 選択した項目がない場合、#ld_CheckList[]をクリアしていなかったのを修正。
• キャンセルした場合、戻り値と#ld_SelectCountを-1に設定するようにした。

2012/12/27 Version 1.5.0

• 削除機能を追加。(メインルーチンの第4引数で設定)
• "SETCTRLITEM"の使い方を間違っていたので修正。(第３引数が数値になっていた。)

2012/12/28

• リストのダブルクリックイベントを有効にできるようにした。(メインルーチンの第5引数で設定) "ld_ListDoubleClickExt"というサブルーチンを呼ぶので、有効にした場合は作成すること。引数　第一引数：項目番号(文字)　　第二引数：項目内容(文字)

このマクロを使用し、

• 表示するリストの作成（$ld_ViewList[]に格納）
• 選択したファイルの処理（$ld_SelectList[]に格納）

を追加すればダイアログを表示するマクロができます。

// リスト表示ダイアログメインルーチン実行に必要なグローバル変数
// $ld_ViewList[]   ：表示する項目を格納した配列
// $ld_SelectList[] ：選択した項目を格納した配列
// #ld_CheckList[]  ：チェックの初期状態/結果を格納する配列(0:チェックなし 1:チェックあり 結果のみ -1:削除)
// $ld_ListCheck    ：チェックしたい項目をカンマ区切りで指定(チェックリストのSETCTRLSTATEを参照)
//                    配列の添え字より +1 された数字を指定する必要あり。
//                    #ld_CheckList[]より優先される。
// #ld_ListMax      ：表示する項目数
// #ld_SelectCount  ：選択された項目数
// #ld_DialogWidth  ：表示するダイアログのサイズ(省略時は80)
//
// 注意  1)配列は必ず0から始めること。
//       2)#ld_ListMaxを設定しない場合、$ld_ViewListに""を含むことは出来ません。(""でリストの終了と見なします。)
//         #ld_ListMaxを設定した場合は、#ld_ListMaxに従います。
//       3)同じ項目内容がある場合、意図した結果にならない場合があります。
//         項目内容でリストの検索を行っている個所があるので、$ld_ViewList[]の先頭からマッチすることになります。
// ---- メインルーチン ListDialog の引数
// $$1：ダイアログに表示するタイトル
// $$2：ダイアログの先頭に表示するメッセージ
// ##3：リストをソートするかしないか。
//      0 ソートしない 
//      1 ソート（田楽の機能）
//      2 変換モジュールを使ったソート 
// ##4：項目削除機能を有効にするかどうかのフラグ
//      0 無効
//      1 有効
// ##5：リストのダブルクリックイベントを有効にするかどうかのフラグ
//      0 無効
//      1 有効
// ---- 戻り値
//-1:キャンセル
// 0:選択なし
// 1:選択あり（結果は$ld_SelectList[]、#ld_CheckList[]の配列に格納）

ダイアログの表示例

目次へ

1.31 マクロから変換モジュールを呼び出す方法

2022/01/19 ソートのパラメータを修正

マクロから変換モジュールを呼びだす方法です。各種変換機能を呼びだすには、filter文を使います。文字変数に対して処理を行う場合は、filter関数を使います。

//変換モジュールを呼びだすマクロの例
filter "Sort.hmf" , "Sort" , "0111";
Sort.hmf：呼び出す変換モジュールの名称(標準の場合は""とする。)
Sort    ：使用する機能名
0111    ：変換モジュールに渡すパラメータ

変換モジュールに解説がある場合は、解説に従います。解説がない場合は、"マクロの記録"を使って記録するのが、手っ取り早いです。詳細は、秀丸エディタのヘルプ「目次－ 動作環境－ 編集－変換」にある、「参考：変換モジュールをキー割り当てする方法」を参照してください。

秀丸エディタ本体で、変換モジュールを使う方法は、 "変換モジュールを使うには" を参照してください。

$a = "4\n3\n2\n1";
$n = filter("Sort.hmf" , "Sort" , "00010",$a);
message "-ソート前-\n" + $a + "\n-ソート後-\n" + $n;

-------------
秀丸エディタ
-------------
-ソート前-
4
3
2
1
-ソート後-
1
2
3
4

-------------
OK   
-------------

1.32 タブに名前をつける

タブに任意の名前をつける方法です。

1.33 マクロメモ

単なるメモ。

2020/09/27 explorerの起動オプションのリンク先変更

0x00800000　秀丸メール上で動作しているかどうか（秀丸メールV5.60以降）

例)画面サイズが80桁×40行の場合で、カーソル位置が50行にある場合。
　NG：enabledraw 80;　表示範囲が80行～120行なので、カーソル位置が画面表示範囲外
　OK：enabledraw 40;　表示範囲が40行～80行なので、カーソル位置が画面表示範囲内 
　NG：enabledraw 0; 　表示範囲が先頭～40行なので、カーソル位置が画面表示範囲外

disabledraw;
  ～
moveto 0,#a;
enabledraw #a;

//          1         2
aaa12345678901234567890

debuginfo 1;
$BAK_SEARCHBUFFER  = searchbuffer;
#BAK_SEARCHOPTION  = searchoption;
#BAK_HILIGHTING    = foundhilighting;
$BAK_REPLACEBUFFER = replacebuffer;
if(#BAK_HILIGHTING) hilightfound 0;
//範囲選択
setcompatiblemode 0x0200;
gofiletop;
searchdown "^a+",regular;
debuginfo "範囲選択 Start:x=" + str(x) + " " + hex(code) + ":" + char(code);
right 5;
debuginfo "範囲選択 End  :x=" + str(x) + " " + hex(code) + ":" + char(code);
//点滅表示
setcompatiblemode 0x0100;
gofiletop;
searchdown "^a+",regular;
debuginfo "点滅表示 Start:x=" + str(x) + " " + hex(code) + ":" + char(code);
right 5;
debuginfo "点滅表示 End  :x=" + str(x) + " " + hex(code) + ":" + char(code);
setsearch $BAK_SEARCHBUFFER, #BAK_SEARCHOPTION;
setreplace $BAK_REPLACEBUFFER;
if(#BAK_HILIGHTING) hilightfound 1;
endmacro;

範囲選択 Start:x=0 61:a
範囲選択 End  :x=7 35:5
点滅表示 Start:x=0 61:a
点滅表示 End  :x=5 33:3

//サンプルマクロ
//No.1
call check getconfig("Font");
//No.2
message getconfig("Font");
//No.3
$get = getconfig("Font");
call check $get;
//No.4
call check "" + getconfig("Font");
endmacro;

check:
    message $$1;
return;
//ここまで

返す値は基本的に文字列型ですが、文字列としても数値としても扱う
ことができます。

//No.1
//空文字と結合させることで、文字列と認識される。
call check "" + getconfig("Font");

#ATTRIBUTE_DIRECTORY = 0x00000010;
$SettingPath = hidemarudir;
openreg "CURRENTUSER", "Software\\Hidemaruo\\Hidemaru\\Env";
if(result){
    $$Pathcheck = getregstr("SettingPath");
    if((existfile($$Pathcheck,1) & #ATTRIBUTE_DIRECTORY) == #ATTRIBUTE_DIRECTORY){
        $SettingPath = $$Pathcheck;
    }
}
closereg;

$in = input("実験","");
#ret = result;
if(#ret == 0){
    message "キャンセルされました。";
    endmacro;
}
if($in == ""){
    message "キャンセルされましたが、\"\"を入力したかもしれません。";
}

//確認用マクロ
openfile currentmacrofilename;
gofiletop;
insert " ";
message "lineupdated(1):" + str(lineupdated);
#main = hidemaruhandle(0);
newfile
gofiletop;
insert " ";
message "lineupdated(2):" + str(lineupdated);
#sub = hidemaruhandle(0);
setactivehidemaru #main;
closehidemaruforced #sub;
quit;
endmacro;

lineupdated(1):1

lineupdated(2):0

test.mac  は、test1.mac を引数付きで起動。
test1.mac は、test2.mac を引数付きで起動。
test2.mac は、test.mac  を引数付きで開く。

message currentmacrobasename + " - execmacro文実行前\n" +
        "引数の数：" + str(argcount) + "\n" +
        "引数 0：" + getarg(0) + "\n"+
        "引数 1：" + getarg(1) + "\n"+
        "引数 2：" + getarg(2) + "\n"+
        "引数 3：" + getarg(3);  
execmacro "test1.mac", "1st", "2nd", "3rd";
message currentmacrobasename + " - execmacro文実後\n" +
        "引数の数：" + str(argcount) + "\n" +
        "引数 0：" + getarg(0) + "\n"+
        "引数 1：" + getarg(1) + "\n"+
        "引数 2：" + getarg(2) + "\n"+
        "引数 3：" + getarg(3);
endmacro;

message currentmacrobasename + " - execmacro文実行前\n" +
        "引数の数：" + str(argcount) + "\n" +
        "引数 0：" + getarg(0) + "\n"+
        "引数 1：" + getarg(1) + "\n"+
        "引数 2：" + getarg(2);
execmacro "test2.mac", "11th", "12th", "13th", "14th";
message currentmacrobasename + " - execmacro文実後\n" +
        "引数の数：" + str(argcount) + "\n" +
        "引数 0：" + getarg(0) + "\n"+
        "引数 1：" + getarg(1) + "\n"+
        "引数 2：" + getarg(2) + "\n"+
        "引数 3：" + getarg(3);
endmacro;  endmacro;

message currentmacrobasename + " - openfile 文実行前\n" +
        "引数の数：" + str(argcount) + "\n" +
        "引数 0：" + getarg(0) + "\n"+
        "引数 1：" + getarg(1) + "\n"+
        "引数 2：" + getarg(2) + "\n"+
        "引数 3：" + getarg(3);
openfile "/a 21th /a 22th /a 23th /a 24th test.mac";
message currentmacrobasename + " - openfile文実行後\n" +
        "引数の数：" + str(argcount) + "\n" +
        "引数 0：" + getarg(0) + "\n"+
        "引数 1：" + getarg(1) + "\n"+
        "引数 2：" + getarg(2) + "\n"+
        "引数 3：" + getarg(3);
endmacro;

test.mac - execmacro文 実行前
引数の数：0
引数 0：
引数 1：
引数 2：
引数 3：

test1.mac - execmacro文 実行前
引数の数：3
引数 0：1st
引数 1：2nd
引数 2：3rd

test2.mac - openfile 文実行前
引数の数：4
引数 0：11th
引数 1：12th
引数 2：13th
引数 3：14th

test2.mac - openfile文実行後
引数の数：4
引数 0：21th
引数 1：22th
引数 2：23th
引数 3：24th

test1.mac - execmacro文 実行後
引数の数：4
引数 0：21th
引数 1：22th
引数 2：23th
引数 3：24th

test.mac - execmacro文 実後
引数の数：4
引数 0：21th
引数 1：22th
引数 2：23th
引数 3：24th

1.34 マクロで文字変数に対する正規表現を使った検索・置換を行う方法

マクロで、文字変数に対して、正規表現を使うには、各種DLLを使用します。

文字変数内にunicodeを含む場合は、dllfunc/dllfuncstr使用時に制限があります。「外部DLL呼び出しとunicode」、「マクロと文字コード」を参照してください。

1.35 浮動小数点バージョン

秀丸エディタVersion.6.50β14より、浮動小数点バージョンから浮動小数点版(統合版)へ、変更になりました。今までの"浮動小数点バージョン"と何処が違うかというと、コマンドにより浮動小数点に切り替わる事です。（"setfloatmode"があると浮動小数点に切り替わります。）通常版よりも多少マクロの動作が遅くなるとのこと。

浮動小数点バージョンで、問題になるのが、数値－文字列変換です。マクロヘルプのsetfloatmode文には以下の説明があります。

－　str関数を使って数値変数を文字列変数に変換すると、小数点以下も付いて表
　　示される。場合によっては指数部付きの形式（+1.234E10のような形式）にな
　　ることがある。

ヘルプには書いてないですが、古いバージョンには以下の続きがあります

（Ｃ言語のsprintf関数で、"%lG"フォーマット使ってます）

"%lG"というフォーマットなので、有効数字は6桁で、これを越えると指数形式に変換されます。

例1) 123000　→　123000
例2) 1230000　→　1.23E+006

秀丸エディタ本体で、これを回避する方法はありません。回避するには、"HideMath.dll"のFormat関数を使用します。 Format関数は、C言語のsprintfと同じで、変換したい形式のフォーマット文字列を指定し、変換を行います。指定できるフォーマット指定方法は、sprintfと同じなので、検索すれば見つかるでしょう。

目次へ

1.36 run文が失敗する

run文が正常に動作しない原因として多いのは、

• 実行するプログラムが空白を含むパスに存在している
• プログラムに渡すファイルが、空白を含んでいる

のどちらかです。

プログラム及び、ファイルに空白を含む場合は、ファイル名を「"」(ダブルクォート)で囲む必要があります。

例１

C:\Program Files\Internet Explorer\IEXPLORE.EXE を実行する場合

NGの例　run "C:\\Program Files\\Internet Explorer\\IEXPLORE.EXE";
OKの例　run "\"C:\\Program Files\\Internet Explorer\\IEXPLORE.EXE\"";

例２

C:\Program Files\Internet Explorer\IEXPLORE.EXE で C:\TEMP\test folder\test.htmlを開く場合。

NGの例1 run "C:\\Program Files\\Internet Explorer\\IEXPLORE.EXE C:\\TEMP\\test folder\\test.html";
NGの例2 run "\"C:\\Program Files\\Internet Explorer\\IEXPLORE.EXE\" C:\\TEMP\\test folder\\test.html";
OKの例　run "\"C:\\Program Files\\Internet Explorer\\IEXPLORE.EXE\" \"C:\\TEMP\test folder\\test.html\"";

目次へ

1.37 ファイル一覧の取得

2011/05/04

COM関連マクロのサンプルのサンプルその７へのリンクを追加

マクロから任意のフォルダから、ファイルの一覧を取得する方法です。

• DLLを使う方法。田楽DLLにはファイルを列挙する関数があるので、これを使用する。
• dirを使う方法。コマンドプロンプトからdirを使用し、その結果を取得し使用する。
• 秀丸エディタのgrepを使う方法。リストに使うには修正が必要。
• COMを使う方法(サンプルその７　秀丸エディタVer.8が必要)

田楽DLLを使う方法は、田楽DLLのヘルプを参照してください。("ENUMDIR"、"ENUMFILE")

1.37.1 dirを使う方法

まず、dirってなに？という人は、コマンドプロンプトを起動して下さい。起動したら">"(プロンプト)が表示されているはずなので、その後に"dir"と入力し、リターンキーを押します。

C:\Documents and Settings\xxxx>dir

すると、ファイルの一覧が表示されます。

dirには様々なオプションがあります。使えるオプションを表示するには"/?"と入力します。

  C:\Documents and Settings\xxxx>dir /?

このオプションでよく使うのは、

• /B ファイル名のみを表示
• /O ファイルを並べ替えて表示(例 名前順 -> /ON 名前逆順 -> /O-N)

場合によっては以下オプションも使います。

• /S 指定されたディレクトリおよびそのサブディレクトリのすべてのファイルを表示

とりあえず "/B"と"/ON"を指定します。

C:\Documents and Settings\xxxx>dir /B /ON

最初の表示と違い、ファイル名だけになります。

この出力を秀丸で使用します。

run getenv("COMSPEC") + " /k dir /b /on \"" + hidemarudir + "\\*.chm\"" + " > con";

be_hidemac.chm
hidemac_html.chm
hidemaru_html.chm
HIDEQA.CHM
hmjre.chm
hmnetex.chm
hmpv.chm
　
C:\xxxx\Hidemaru\macro>

$file = gettext2(0,lineno,linelen2,lineno);

//マクロを実行する秀丸エディタのウィンドウハンドルを保存
#main = hidemaruhandle(0);
//dir結果を取り込む秀丸エディタを非表示で開き、ウィンドウハンドルを保存
//この時点で、新しく開いた秀丸エディタ上でマクロが実行される。
openfile "/n /h ";
#sub = hidemaruhandle(0);
//dirコマンド実行　実際には内部コマンドなので、cmd.exe/command.com 経由で実行
run getenv("COMSPEC") + " /k dir /b /on \"" + hidemarudir + "\\*.chm\"" + " > con";
//ファイルの先頭に移動
gofiletop;
#cnt = 0;
//ファイル名が取得できなくなるまで1行づつ移動
while(1){
    golinetop;
    $text = gettext2(0,lineno,linelen2,lineno);
    if($text != ""){
        $help[#cnt] = $text;
        #cnt = #cnt + 1;
    }else{
        break;
    }
    //dowmでも問題ないかも知れないが、念のためmovetolinenoを使う。
    movetolineno 0, lineno + 1;
}
//マクロを起動した秀丸エディタに移動
setactivehidemaru #main;
//dirを実行した秀丸エディタを強制的に閉じる
closehidemaruforced #sub;
//取り込んだファイル名をメニューで表示
menuarray $help, #cnt;
#sel = result;
if(#sel == 0){
    endmacro;
}else{
    //ヘルプを起動
    run "rundll32.exe url.dll,FileProtocolHandler " + "\"" + hidemarudir + "\\" + $help[#sel - 1] + "\"";
}

command >output_file 2>&1

1.38 開いているファイルに対する処理の注意点

秀丸エディタで開いているファイル全てに対して、処理を行う場合の注意点です。 (単純な事なんですが、各ウィンドウの状態を見ておかないと、失敗する可能性が大きい。)

開いているファイル全てに対して、処理を行う場合は以下のマクロを使います。

#i = 0;
while( #i < hidemarucount) {
  //処理したい内容を記述
  nexthidemaru;
  #i = #i + 1;
}

しかし、問題がないわけではありません。 hidemarucountは、常駐秀丸エディタを除く、起動している秀丸エディタの数を返しますが、 nexthidemaruは、最小化している秀丸エディタには移動しません。その為、最小化した秀丸エディタがいる状態で、上記マクロを使用すると、移動回数と実際に移動できるウィンドウの数が一致しないため、同じファイルに対して、複数回処理を行う事になります。

例）開いている秀丸の数　　：３
　　最小化している秀丸の数：１
　　移動する回数：３（hidemarucount = 3）
　　１回目：１→２
　　２回目：２→１（最小化しているので、３へ行かない）
　　３回目：１→２

確実に全てのファイルに処理を行うには、nexthidemaruではなく、nexthidemaruiconを、使う必要があります。

#i = 0;
while( #i < hidemarucount) {
  //処理したい内容を記述
  nexthidemaruicon;
  #i = #i + 1;
}

ちなみに、通常操作ではありえませんが、非表示状態の秀丸エディタがいる場合、 nexthidemaruiconを使用しても、移動できません。移動するには、hidemaruhandleを取得して、setactivehidemaruを使用する必要があります。

秀丸エディタで、ウィンドウを切り換えて処理を行う場合、nexthidemaruiconを使用せずに、 hidemaruhandleとsetactivehidemaruを、使用した方がいいかもいれません。

おまけに、アクティブなタブグループに対して処理する方法。

#i = 0;
while( #i < tabtotal) {
  //処理したい内容を記述
  nexttab;
  #i = #i + 1;
}

tabtotal自体、"このタブを最小化"と非表示を認識しないので、上記のような問題はない。

目次へ

1.39 INIファイル関連

2015/11/15

iniファイルとUnicodeを修正

マクロで設定を保存する場合、INIファイルを使う場合がある。セクション名、キー名がわかっている場合はいいが、わからない場合は、直接秀丸エディタで開き、検索を使って、セクション名、キー名を列挙する。

//セクション名の列挙
$BAK_SEARCHBUFFER  = searchbuffer;
#BAK_SEARCHOPTION  = searchoption;
gofiletop
while(1){
    searchdown2 "^\\[([^\\]]+)\\](?\\1)",regular;
    if(!result) break;
    message gettext(foundtopx, foundtopy, foundendx, foundendy,1);
    moveto foundendx, foundendy;
}

setsearch $BAK_SEARCHBUFFER, #BAK_SEARCHOPTION;
setreplace $BAK_REPLACEBUFFER;
endmacro;

キー名も基本的に同じだが、セクション名と違い、セクションの範囲内のみ検索する必要がある。

//セクション名、キー名の列挙
$BAK_SEARCHBUFFER  = searchbuffer;
#BAK_SEARCHOPTION  = searchoption;
gofiletop
while(1){
    //セクションの検索
    searchdown2 "^\\[([^\\]]+)\\](?\\1)",regular;
    if(!result){
        message "セクションが見つかりません。";
        break;
        endmacro;
    }
    $section = gettext(foundtopx, foundtopy, foundendx, foundendy);
    #st_y = y + 1;
    //セクションの終端を検索
    searchdown2 "^\\[([^\\]]+)\\](?\\1)",regular;
    if(!result){
        gofileend;
    }else{
        golinetop2;
    }
    #en_y = y;
    moveto 0,#st_y;
    while(y < #en_y){
        golinetop2;
        if(code == '[') break;
        if(code == eof) break;
        if(code != ';'){
            selectline;
            searchdown2 "^([^=]+)",regular,inselect;
            if(result){
                $key = gettext(foundtopx, foundtopy, foundendx, foundendy);
            }
            message "section=" + $section + "\n" + "key=" + $key;
        }
        movetolineno 0, lineno + 1;
    }
}
setsearch $BAK_SEARCHBUFFER, #BAK_SEARCHOPTION;
setreplace $BAK_REPLACEBUFFER;
endmacro;

[section]
key=value

[test]
ク=これは「ク」です。
ハ=これは「ハ」です。

message getinistr(currentmacrodirectory + "\\test.ini", "test", "ハ");

---------------------------
秀丸エディタ
---------------------------
これは「ク」です。
---------------------------
OK   
---------------------------

1.40 findhidemaruでファイルが見つからない

2007/07/05

内容修正

以下の内容は、秀丸エディタVer.7.00β15以降では発生しません。 (Ver.7.00β15で、ショートファイルネームでfindhidemaruが可能になりました。)

秀丸エディタで開いているファイルの中に、指定したファイルがあるかどうかを、調べる方法として、 findhidemaru文がありますが、秀丸エディタでファイルを開いているのに、findhidemaru文で、見つけられない場合があります。

サンプルマクロ

//ウィンドウハンドルを取得
#main = hidemaruhandle(0);
//ファイル名を作成
$newname = hidemarudir + "\\test0123456789.txt";
//ファイルを開く
openfile $newname;
insert "test!!";
save;
//普通の(?)ファイル名
$searchname1 = filename;
//ショートファイル名
$searchname2 = filename3;
//ウィンドウハンドルを取得
#sub = hidemaruhandle(0);
//findhidemaruは自分自身を対象にしない為、秀丸エディタを切り換える。
//$newnameを開いている秀丸エディタを検索
setactivehidemaru #main;
#n = findhidemaru($searchname1);
if(#n == -1){
    message $searchname1 + "が見つかりません！！";
}else{
    message $searchname1 + "が見つかりました。";
}
//ショートファイルネームで検索
#n = findhidemaru($searchname2);
if(#n == -1){
    message $searchname2 + "が見つかりません！！";
}else{
    message $searchname2 + "が見つかりました。";
}
//開いたファイルを閉じて削除
closehidemaruforced #sub;
run getenv("COMSPEC") + " /C del \"" + $searchname1 + "\" >nul";
endmacro;

このマクロを実行すると、最初に「～が見つかりました。」と表示され、次は「～が見つかりません！！」と表示されます。（表示されるはずです。）

一回目と、二回目の違いは、検索で指定するファイル名の違いで、見つからない二回目は、ショートファイルネームを使って検索しています。

findhidemaru文には、ショートファイルネームではなく、ロングファイルネームを指定しないと、検索に失敗するようです。

目次へ

1.41 自動起動マクロ関連

2013/01/12「ファイルを開いた状況の判定」を修正。「通常操作以外の自動起動マクロ」を追加

自動起動マクロに関する情報やメモ

test.mac(自動起動)
　↓
test1.mac(test.macからexecmacroで起動)
　↓
test2.mac(test1.macからexecmacroで起動)

(event == 1) && (geteventparam(0) == 0) && (getresultex(7) == lineno)

filetype[1] == "grep"

1.42 「ブラウザの指定」で指定するプログラム

通常は、ブラウザを指定しますが、スクリプトも指定可能です。(確認したのはWSH)

C:\Windows\system32\wscript.exe scriptfullpath.vbs

と指定しておくと、URLを引数にして、スクリプトが起動します。

URLのカスタマイズと、スクリプトを併用すれば、用途が増えそう。

• 特定のURLだけ、別のブラウザで開く
• 特定のプロトコルを別のアプリケーションで起動する
  例)"ms-help://"ならdexplore.exeを起動する (秀丸エディタ Ver.8のヘルプに、COM経由でdexplore.exeを起動する例があります。)

サポートフォーラムでの例

• hidesoft.2:24571　「ttp://」への対応
• hidesoft.8:35473　ブラウザの使い分け

目次へ

1.43 アウトライン関連

• 2019/03/17:「アウトライン解析の枠」の大きさを追加

関連項目

• レジストリの内容　アウトライン解析の枠
• 「ツリーそのものをコピー」のTAB-罫線変換マクロ
• アウトラインの設定

#n = getconfig("Outline");
if(#n == 0){
    message "枠が表示されていません。";
}else{
    message "枠が表示されています。";
}

非表示：outlinehandle = 0
表示　：outlinehandle = 0以外

#a=sendmessage( #hwnd, 0x0111,7171,0);

message gettitle(4);

#ret = sendmessage(hidemaruhandle(0),0x0111, 338,0);

1.44 ファイルタイプ別の設定関連

現在開いているファイルで使用している、「ファイルタイプ別の設定」の設定は、 "currentconfigset"で取得可能。 "currentconfigset"は、config文で設定を変更しても(一時的な変更でも)保持される。現在の設定が"一時的な設定"かどうかは、"configstate"で確認可能。 "一時的な設定"を解除するには、configset文を使用し"再設定"するか、ファイルを一度閉じ、再度開く。(再読み込みでは不可)

任意の拡張子に関連付けられた、「ファイルタイプ別の設定」を取得するには、レジストリを見る。 "CURRENTUSER"にある"Software\Hidemaruo\Hidemaru"の下に、拡張子毎のノードが作成され、設定名が保存されている。レジストリを触りたくない場合は、調べたい拡張子をつけたダミーファイルを開き、 "currentconfigset"を調べればいい。

目次へ

1.45 新規ファイルの判定

"無題"の新規ファイルの場合、filetypeは"new"になります。しかし、起動時に、存在しないファイル"test.txt"を指定すると、新規ファイルですが、filetypeは".txt"になります。

hidemaru.exe test.txt

つまり、新規ファイルだけど、filetypeで判定ができない場合があります。

この様な場合に、新規ファイルの判定を行うには、タイトルバーの内容を使います。秀丸エディタ Ver.7.00で、gettitle関数が追加され、表示中のタイトルバーの内容が、取得可能になりました。上記の方法で、存在しないファイル"test.txt"を指定し、タイトルバーの内容を取得すると、以下のようになります。

test.txt (新規) - 秀丸

gettitle関数で取得した内容に、"(新規) - 秀丸"が含まれている場合、起動時に存在しないファイルを指定されたと、判断ができます。ほとんどないと思いますが、ファイル名に"(新規) - 秀丸"という文字列が含まれる場合を考慮し、厳密にチェックした方がいいのかもしれません。

自動起動マクロの「新規作成直後」は、存在しないファイルを指定した場合でも、正常に起動します。

起動時に、ファイルのエンコード指定があり、タイトルバーにエンコードの種類や、改行を表示する設定になっている場合、取得文字列が変わります。

起動時の指定　　：hidemaru.exe /fs test.txt
取得できる文字列：test.txt (新規) [Shift-JIS] [CR+LF] - 秀丸

2009/08/13追加
単純に、existfile で調べるという方法もあります。秀丸エディタは、保存するまでは、ファイルの生成を行わないので、ファイルの有無を調べる事で判定が可能です。

2010/04/25追加
参考までに、各状態で取得できるファイル名関連のキーワード

• 新規ファイルの場合

  タイトルバーの内容:    (無題) [Shift-JIS] [CR+LF] - 秀丸
  ********** ファイル名関連キーワード
  filename:              
  basename:              
  directory:             d:\temp
  filetype:              new
  filename2:             
  basename2:             
  directory2:            D:\temp
  filename3:             
  basename3:             
  directory3:            d:\temp

• 存在しないファイルを指定して開いた場合

  タイトルバーの内容:    D:\temp\test.txt (新規) [Shift-JIS] [CR+LF] - 秀丸
  ********** ファイル名関連キーワード
  filename:              d:\temp\test.txt
  basename:              test.txt
  directory:             d:\temp
  filetype:              .txt
  filename2:             D:\temp\test.txt
  basename2:             test.txt
  directory2:            D:\temp
  filename3:             d:\temp\test.txt
  basename3:             test.txt
  directory3:            d:\temp

目次へ

1.46 折りたたみ関連

1.47 COM関連

2018/03/11　COM作成関連、サンプルその９ のリンクを修正

秀丸エディタVer.8.00より、COM関連のマクロが追加され、秀丸マクロ上から、各種COMの操作が可能になります。

• Windows 98 以降は、Windows Script Host(WSH)が標準で搭載されているので、 WSHの各種機能が使用可能です。
• Internet Explorer も COMから操作可能です。
• Windows 2000 以降なら、Windows Management Instrumentation (WMI)も使用可能です。

参考になるMicrosoftのwebサイト

• スクリプト センター

参考になる各種webサイト

• Windows Script Programming
• ACCESS/EXCEL/VBScript/VBAプログラミング講座＆Tips(2016/09/06現在アクセス不可)
• Whitire's HomePage
• WMI Fun !!

現状での問題点等

• オブジェクトを引数に指定できない。(サイトー企画さんへは連絡済み。対処待ち)
  秀丸エディタ Ver.8.20β23より、「allowobjparam文」が追加され、パラメータにオブジェクトや、バイナリデータを指定することが可能になりました。

00013|#Browser = createobject("Sleipnir.API");
00014|if(#Browser == 0){
00015|    $ERR =  "Sleipnirオブジェクト作成に失敗";
00016|    goto ERRMSG;
00017|}

00013|#Browser = createobject("Lunascape2.LunascapeAPI");
00014|if(#Browser == 0){
00015|    $ERR =  "Sleipnirオブジェクト作成に失敗";
00016|    goto ERRMSG;
00017|}

//表示状態の設定
#SW_HIDE            = 0; //非表示にする。他のウィンドウがアクティブになる。
#SW_SHOWNORMAL      = 1; //アクティブにして表示する。
#SW_SHOWMINIMIZED   = 2; //アクティブにして最小化する。
#SW_SHOWMAXIMIZED   = 3; //アクティブにして最大化する。
#SW_SHOWNOACTIVATE  = 4; //直前の状態（位置・大きさ）に戻す。SW_NORMALとほぼ同じだが、アクティブ化はしない。
#SW_SHOW            = 5; //表示する。アクティブ化も行う。
#SW_MINIMIZE        = 6; //最小化する。他のウィンドウがアクティブになる。
#SW_SHOWMINNOACTIVE = 7; //最小化する。アクティブ化は行わない。
#SW_SHOWNA          = 8; //表示する。SW_SHOWと同じだが、アクティブ化はしない。
#SW_RESTORE         = 9; //直前の状態（位置・大きさ）に戻す。
#SW_SHOWDEFAULT     = 10; //アプリケーション起動時のデフォルト状態に戻す。

#WshShell = createobject("WScript.Shell");
if(#WshShell == 0){
    message "WshShellオブジェクトの作成に失敗しました。";
    endmacro;
}
//アクティブウィンドウを切り替えないで、最小化状態でメモ帳開く。
//#SW_SHOWMINIMIZEDの場合は、メモ帳側にアクティブなウィンドウが切り替わってしまう。
callmethod #WshShell, "Run", "notepad.exe", #SW_SHOWMINNOACTIVE, false;
releaseobject #WshShell;

Wscript.echo "戻り値のテスト"
Wscript.quit(100)

#ret = callmethod_returnnum(#WshShell, "Run", "wscript test.vbs", #SW_SHOWNORMAL, true);
message str(#ret);

1.48 CSV、TSVモード

作成：2009/09/20　更新：2010/04/08 CSV、TSVモードの判定方法を追加

CSV、TSVモードのメモ

#TabMode = getconfig("TabMode")

if((0x000f & #TabMode) == 0x0000){
  //通常モード
}else if((0x0f0f & #TabMode) == 0x0001){
  //TSVモード
  
}else if((0x0f0f & #TabMode) == 0x0101){
  //CSVモード
  
}

1.49 ファイルマネージャ枠とアウトプット枠

作成：2013/06/29　更新：2013/06/29 アウトプット枠に、リンク追加

ファイルマネージャ枠とアウトプット枠のメモ

非表示

秀丸エディタ本体に、各枠のDLLが読み込まれているが、表示されていない状態

未ロード

秀丸エディタ本体に、各枠のDLLが読み込まれていない状態

1.50 マクロと文字コード

作成：2010/03/30　更新：2015/03/21 マクロファイル自体の文字コードについて を修正

主にShift_JISとUnicodeに関してです。他の文字コードに関しては、使ってないのでよくわかりません。

$a = "森鷗外";// "鷗" は Shift_JISにはない文字
message $a + "\nstrlen:" + str(strlen($a)) + "\nwcslen:" + str(wcslen($a)); //--> 6 と 3 が表示される。

---------------------------
表示される内容
---------------------------
森鷗外
strlen:6
wcslen:3
---------------------------

$a = "森鷗外𠘨";// "鷗" は Shift_JISではない文字、"𠘨"は UTF-16LEでサロゲートペア(2文字)で表現される文字
message $a + "\nstrlen:" + str(strlen($a)) + "\nwcslen:" + str(wcslen($a)); //--> 8 と 5 が表示される。

---------------------------
表示される内容
---------------------------
森鷗外𠘨
strlen:8
wcslen:5
---------------------------

上位サロゲート範囲    0xD800～0xDBFF
下位サロゲート範囲    0xDC00～0xDFFF

//𡵢のサロゲートペア値
$b = "\uD847\uDD62";
message $b + "\n" + hex(unicode($b)) + "\n" + hex(unicode(wcsmidstr($b, 0, 1)));

𡵢
21D62
D847

//英字、漢字、Unicodeのみ存在する文字、サロゲートペアで表現している文字を一文字ずつ分解する例
$a = "abc森def鷗gh外ij𠘨k";
$out = "";
#cnt = 0;
#pos = 0;
#len = wcslen($a);
while(#len > #pos){
    $b = wcsmidstr($a, #pos, 1);
    if($b == "") break;
    #d = unicode($b);
    //サロゲートペアの上位側かチェックする
    if((0xD800 & #d) == 0xD800){
        //上位側なら、下位バイトを含め取得し直す
        $b = wcsmidstr($a, #pos, 2);
        #d = unicode($b);
        #pos = #pos + 1;
    }
    #pos = #pos + 1;
    #cnt = #cnt + 1;
    $out = $out + rightstr("00" + str(#cnt), 2) + ":" + $b + "\n";
}
message $out;
endmacro;

$a = "森鷗外1𠘨2";
loaddll hidemarudir + "\\hmjre.dll";
if(!result){
    message "DLLのロードに失敗";
    endmacro;
}
//"2"を検索する。
#a = dllfunc("FindRegular", "2", $a, 0);
#c = strstr($a, "2");
  
message str(#a) + "-> FindRegularの結果\n" + str(#c) + " -> strstrの結果\n";
endmacro;

---------------------------
表示される内容
---------------------------
17-> FindRegularの結果
9 -> strstrの結果
---------------------------
//                1
//      012345678901234567   hmjre.dllが認識している状態
//$a = "森鷗..外1𠘨......2";
//      0123456789           マクロ関数が認識している状態
//$a = "森鷗外1𠘨2";

$a = "森鷗外1𠘨2";
loaddll hidemarudir + "\\hmjre.dll";
if(!result){
    message "DLLのロードに失敗";
    endmacro;
}
//7バイト目から検索するので、"2"にマッチするのを期待している。
#a = dllfunc("FindRegular", "\\d", $a, 7);
#len = dllfunc( "GetLastMatchLength");
$a1 = midstr( $a, byteindex_to_charindex($a,#a), #len);
  
message str(#a) + "バイト目\n\"" + $a1 + "\" -> FindRegularの結果";
endmacro;

---------------------------
表示される内容
---------------------------
8バイト目
"1" -> FindRegularの結果
---------------------------
//                1
//      012345678901234567   hmjre.dllが認識している状態
//$a = "森鷗..外1𠘨......2";
//      0123456789           マクロ関数が認識している状態
//$a = "森鷗外1𠘨2";

$a = "森鷗外1𠘨2";
loaddll hidemarudir + "\\hmjre.dll";
if(!result){
    message "DLLのロードに失敗";
    endmacro;
}
//"2"を検索する
#a = dllfunc("FindRegular", "2", $a, 0);
#n = dllfunc("SetUnicodeIndexAutoConvert", 1);
#b = dllfunc("FindRegular", "2", $a, 0);
#c = strstr($a, "2");
  
message str(#a) + "-> FindRegularの結果\n" + str(#b) + " -> FindRegularの補正された結果\n" + str(#c) + " -> strstrの結果\n";
endmacro;

---------------------------
表示される内容
---------------------------
17-> FindRegularの結果
9 -> FindRegularの補正された結果
9 -> strstrの結果
---------------------------
//                1
//      012345678901234567   hmjre.dllが認識している状態
//$a = "森鷗..外1𠘨......2";
//      0123456789           マクロ関数が認識している状態
//$a = "森鷗外1𠘨2";

$a = "森鷗外1𠘨2";
loaddll hidemarudir + "\\hmjre.dll";
if(!result){
    message "DLLのロードに失敗";
    endmacro;
}
//7バイト目から検索するので、"2"を取得するのを期待している。
#n = dllfunc("SetUnicodeIndexAutoConvert", 1);
#a = dllfunc("FindRegular", "\\d", $a, 7);
#len = dllfunc( "GetLastMatchLength");
$a1 = midstr( $a, #a, #len);
  
message str(#a) + "バイト目\n\"" + $a1 + "\" -> FindRegularの結果";
endmacro;

---------------------------
表示される内容
---------------------------
9バイト目
"2" -> FindRegularの結果
---------------------------
//      0123456789           マクロ関数が認識している状態
//$a = "森鷗外1𠘨2";
  
DLL内で補正が有効になり、マクロ関数と同じ値となる。

1.51 プロジェクトファイルについて

作成：2010/04/17　更新：2010/05/05

プロジェクトファイルのフォーマットについてのメモ

• 基本的に(ファイルマネージャ枠から保存すると)Unicode(UTF-16LE)で保存される。 Shift_JISでも、読み込ませるのには問題はない。
• プロジェクトファイルの先頭には、「//directory="プロジェクトを保存したフォルダ"」という記述がありますが、なくてもいいが、あった方がいいとのこと。
  (turukame.3:05572)

ファイル

"ファイルパス",name="枠に表示する名前"

セパレータ

---------- ("-"×10個)

グループ

"グループ名",group[,expand] ",expand"が付くと展開して表示される

フォルダ内のファイル一覧

"ファイルパス+ワイルドカード",name="枠に表示する名前",folder

レベルは、タブ(0x09)コードの数で表現される。

プロジェクトファイルの中身１

"File1",name="File1"
"Group",group,expand
(tab) "File2",name="File2"
(tab) ----------
(tab) "File3",name="File3"
----------
"File4",name="File4"

プロジェクトの表示１

┌ File1
├ Group
│├ File2
│├ ----------
│└ File3
├ ----------
└ File4

タブを間違って消すと、途中でレベルがおかしくなる。

プロジェクトファイルの中身２

"File1",name="File1"
"Group",group,expand
(tab) "File2",name="File2"
----------
(tab) "File3",name="File3"
----------
"File4",name="File4"

プロジェクトの表示２

┌ File1
├ Group
│└ File2
├ ----------　←
├ File3     　←レベルが一段下なのに、無視されている。
├ ----------
└ File4

タブを間違って追加すると、アイコンがおかしくなる場合がある。

正常な場合

───────────
"Gr01",group,expand
(tab) "File-11",name="File-11"
(tab) "File-12",name="File-12"
(tab) "File-13",name="File-13"
"File-01",name="File-01"
"File-02",name="File-02"
───────────
┌Gr-01
│├file-11
│├file-12
│└file-13
├file-01
└file-02

異常な場合

───────────
"Gr01",group,expand
(tab) "File-11",name="File-11"
(tab) (tab) "File-12",name="File-12"  ← タブを追加
(tab) "File-13",name="File-13"
"File-01",name="File-01"
"File-02",name="File-02"
───────────
┌Gr-01
│├file-11   ← グループのアイコンになる。
││└file-12
│└file-13
├file-01
└file-02

目次へ

1.52 カラーマーカーのレイヤー

作成：2013/07/07　更新：2018/09/14

• レイヤーを指定して、カラーマーカーをつけても、colorcodeキーワードで検出可能。 (レイヤーに関係なく、カラーマーカーの検出は可能)

• colorcodeキーワードで検出は可能だが、どのレイヤーにカラーマーカーが付いているか調べるには、 enumcolormarkerlayer関数で、あらかじめレイヤーを取得しておき、getcolormarker関数でレイヤーを指定し、戻り値をチェックする。

  $n = getcolormarker(0x01, "レイヤー名");

  getcolormarker(0x01) の戻り値は、カラーマーカーが設定されていない場合は、""(空文字) を返す。これはレイヤーを指定した場合も同じ。 (文字色に透明を指定しても、-1(0xFFFFFF)を返してくるので、「透明」とは区別可能) 同じ文字に複数のレイヤーで色付けしている場合もあるので、全てのレイヤーでチェックする事。

  秀丸エディタ Ver.8.85 より、getcolormarker 関数の第一引数のフラグが追加されている。 0x100 を指定すると、一番上のレイヤー名を取得可能になった。その為、総当たりしなくても、それより下のレイヤーを調べればいい。

• 複数のレイヤーがある場合、新しく追加されたレイヤーが上になる。現状では、レイヤーの順番を入れ替える方法はない。(レイヤーの上下関係を操作する命令は存在しない。)

  enumcolormarkerlayer で 0から得られる順番は、

  追加したレイヤー順 = 下にあるレイヤー

  という順番になる。

• getcolormarker で 0x10 を指定しても、レイヤー上の文字色は取得出来ない。レイヤーを使用している場合、現在表示されている色を取得するには、一番上のレイヤーから、情報を取得すること。(透明な場合は、その下の色となるので、上から順番にチェックすることになる。)

"6)"は、一番最下層にあるレイヤー(一番最初に追加したレイヤー)「layer1」に、カラーマーカを設定しているので、他のレイヤーが上に重なっていて、見えていない状態になっている。

目次へ

1.53 選択範囲内で、複数回の全置換を行う

作成：2015/04/11　更新：2021/08/02(「範囲内検索を選択」を使う方法を追加)

選択範囲内で、複数回の全置換を行う方法です。

サンプルデータ

hidemaru1 hidemaru2 hidemaru3 秀丸A
hidemaru4 hidemaru5 hidemaru6
hidemaru7 hidemaru8 hidemaru9 秀丸B

サンプルマクロ ここから

setcompatiblemode 0x20000;
replaceallfast "hidemaru" , "秀丸" ,inselect ,regular;// 1回目
replaceallfast "秀丸" , "HIDEMARU" ,inselect ,regular;// 2回目
endmacro;

2行目を選択してマクロを実行した結果(希望の結果)

hidemaru1 hidemaru2 hidemaru3 秀丸A
HIDEMARU4 HIDEMARU5 HIDEMARU6
hidemaru7 hidemaru8 hidemaru9 秀丸B

2行目を選択してマクロを実行した結果(実際の結果)

hidemaru1 hidemaru2 hidemaru3 HIDEMARUA
HIDEMARU4 HIDEMARU5 HIDEMARU6
hidemaru7 hidemaru8 hidemaru9 HIDEMARUB

2行目を選択し、2行目だけ置換を行うつもりで上記マクロを実行しても、2回目は全体が置換されます。これは、以下のような動作になっているからです。

1. 1回目実行時は、範囲選択されているので、"inselect"が有効、二行目のみ処理。
2. 置換処理を行ったため、1回目実行後は範囲選択が解除されている状態。
3. 2回目実行時は、範囲選択されていないので"inselect"が無効、対象が全体になる。
   「replaceallfast」は、指定された内容で、各種検索オプションを変更します。その為、「選択した範囲内のみ」の状態も変更しようとしますが、2回目の命令実行時は、範囲選択が解除されているので、結果的に「選択した範囲」が無い状態になっている。

という事で、範囲選択している個所に複数回の全置換を行うには、工夫が必要です。

• finddown/findupを使う

  finddown/findupは、実行時に各種検索オプションがそのまま有効で、オプションを変化させません。 (そのため「選択した範囲内のみ」の範囲も保持される。)

  注意点としては、以下になります。

  • 範囲内を対象とするには、対象がマッチしなくなるまで、コマンドを繰返し実行する必要がある。

  • 検索開始位置を保持しておく必要がある。マッチした箇所にカーソルが移動してしまうので、複数回実行するには、検索開始位置にカーソルを戻す必要がある。

    setcompatiblemode (0x20000);                  //検索オプションを保持
    #screentopy = screentopy;                     //画面の先頭行を保持
    disabledraw;                                  //画面描画無効
    if(selecting){                                //範囲選択中かチェック
        #x = seltopx;                             //範囲選択中なら、先頭位置を取得
        #y = seltopy;
        forceinselect 1;                          //「選択した範囲内のみ」に設定
    }else{
        gofiletop;                                //範囲選択していないなら、ファイルの先頭へ移動
        #x = x;                                   //先頭座標を取得
        #y = y;
        if(inselecting) escapeinselect;           //「選択した範囲内のみ」を解除
    }
    call REPLACE_WORK #x, #y, "hidemaru", "秀丸"; //置換その１
    call REPLACE_WORK #x, #y, "秀丸", "HIDEMARU"; //置換その２
    if(inselecting) escapeinselect;               //「選択した範囲内のみ」を解除
    moveto 0,#screentopy;                         //カーソル移動
    enabledraw #screentopy;                       //画面描画有効
    endmacro;
    //実際に置換処理を行うサブルーチン
    REPLACE_WORK:
        setsearch $$3, (searchoption|0x00000004); //検索対象と、置換フラグをセット その他必要なオプションはここで設定する事
        setreplace $$4;                           //置換文字をセット
        ##ret = true;
        while(##ret){                             //見つからなくなるまで、検索・置換を実行
            finddown2;                            //カーソル位置から検索するので、finddown2 を使う。
            ##ret = result;
        }
        moveto ##1, ##2;                          //置換開始位置に移動
    return;

• 部分編集を使う

  選択範囲が行単位の場合は、部分編集が使えます。

  部分編集を使うと、編集対象は部分編集中の箇所になるので、 replaceall/replaceallfast文の対象を限定できます。

  ただし、マクロの互換性から、普通にreplaceall/replaceallfast文を実行すると、部分編集中でも部分編集が解除されてしまいます。(部分編集外も検索置換対象になる。)

  その為、明示的に部分編集のみを対象とするように、指示を行う必要があります。その指示は、「setcompatiblemode」文を使用します。

  setcompatiblemode (0x20000|0x000C);

  また、部分編集になると画面が、部分編集モードに切り替わってしまいます。それが気になる場合は、画面の描画を制御してください。

  欠点としては、すでに部分編集を行っていた場合、部分編集が解除されてしまう事です。 (マクロで、状況を調べ元の部分編集に戻す事は可能でしょう)

  setcompatiblemode (0x20000|0x000C);           //検索オプションを保持し、部分編集を解除しない
  #screentopy = screentopy;                     //画面の先頭行を保持
  disabledraw;                                  //画面描画無効
  if(selecting) rangeeditin;                    //範囲選択していたら部分編集へ
  replaceallfast "hidemaru" , "秀丸" , regular; //置換その1
  replaceallfast "秀丸" , "HIDEMARU" , regular; //置換その2
  if(rangeeditmode != 0) rangeeditout;          //部分編集中なら解除する
  moveto 0,#screentopy;                         //カーソル移動
  enabledraw #screentopy;                       //画面描画有効
  endmacro;

• カラーマーカーを使う

  選択範囲が行単位ではない場合は、カラーマーカーを使います。

  選択範囲にカラーマーカーをつけて、「追加の条件」から「範囲の指定/カラーマーカー内」をチェックし、「「一時的なカラーマーカー」の範囲」を指定する事で、replaceall/replaceallfast文の対象をカラーマーカーの範囲内に限定させます。カラーマーカーは、「編集したら削除」をOFFの状態で設定すれば、置換でカラーマーカーが削除されることはありません。

  setcompatiblemode 0x20000;                      //検索オプションを保持
  #screentopy = screentopy;                       //画面の先頭行を保持
  $taegetlayer = "replaceall";                    //レイヤー名の設定
  $backuplayer = "";                              //設定のバックアップ
  disabledraw;                                    //画面描画無効
  if(selecting){                                  //範囲選択されていた場合
      colormarker -1, -1, 0, 0, 0, $taegetlayer;  //文字色、背景色を透明、普通、編集しても維持、で指定したレイヤー名に設定
      $backuplayer = targetcolormarker;           //追加の条件を保存
      settargetcolormarker $taegetlayer;          //追加の条件で対象になるレイヤーを指定
  }
  replaceallfast "hidemaru" , "秀丸" , regular, incolormarker; //置換その1(incolormarker を指定すること)
  replaceallfast "秀丸" , "HIDEMARU" , regular, incolormarker; //置換その2(incolormarker を指定すること)
  if(targetcolormarker == $taegetlayer){          //対象レイヤーが指定したレイヤーの場合
      deletecolormarkerall $taegetlayer;          //レイヤーないのカラーマーカーを全部削除
      settargetcolormarker $backuplayer;          //設定を復元
  }
  moveto 0,#screentopy;                           //カーソル移動
  enabledraw #screentopy;                         //画面描画有効
  endmacro;

• 「selectinselect(範囲内検索を選択)」を使う(Ver.8.98以降の場合)

  Ver.8.98から、「選択した範囲」で指定した領域を選択する命令「範囲内検索を選択(selectinselect)」が追加されています。それを使えば、置換 → 再度選択 → 置換 と繰り返す事が可能です。

  setcompatiblemode 0x20000;
  //範囲選択していた場合は、「inselect」が有効
  replaceallfast "hidemaru" , "秀丸" ,inselect ,regular;// 1回目
  //範囲選択していた範囲を再度選択状態へ
  selectinselect;
  //範囲選択状態なので、「inselect」が有効
  replaceallfast "秀丸" , "HIDEMARU" ,inselect ,regular;// 2回目
  endmacro;

目次へ

top＞秀丸エディタマクロ＞